EXTRAIR.REGEX

A função EXTRAIR.REGEX tem como resultado as correspondências ou grupos de captura no resultado de uma determinada expressão regular numa cadeia de origem.

EXTRAIR.REGEX(cadeia-origem; cadeia‑expressão‑regular; ocorrência-correspondência; ocorrência-grupo-captura)

cadeia-origem: um valor de cadeia para correspondência.

cadeia‑expressão‑regular: um valor de cadeia que representa uma expressão regular, usada para correspondência da cadeia-origem.

ocorrência-correspondência: um número inteiro opcional que indica o resultado que deve ser devolvido, caso existam vários resultados. São aceites números inteiros negativos e permitem aceder inversamente às correspondências, por isso -1 é a última correspondência, etc. Se 0 for introduzido, tem como resultado uma tabela de todas as correspondências. Se for omitido, tem como resultado a primeira correspondência.

ocorrência-grupo-captura: um número inteiro opcional que indica o grupo de captura que deve ser devolvido dentro de um resultado, caso existam grupos de captura na expressão regular. Os valores negativos não são aceites. Se o resultado for 0, tem como resultado uma tabela de todos os grupos de captura. Se for omitido, tem como resultado a correspondência inteira.

Notas

A cadeia‑expressão‑regular tem de estar em conformidade com a norma ICU.

Exemplos
Se tiver dados que não podem ser facilmente colocados nas linhas e colunas de uma folha de cálculo, pode usar EXTRAIR.REGEX para simplificar. Por exemplo, na tabela abaixo, os dados têm alguma estrutura, mas pode ser difícil separar os dados manualmente em várias células para revisão.

	A
1	Opiniões dos utilizadores
2	E-mail: jtalma@icloud.com Nome: Julie Talma Data: 17/05/2019
3	E-mail: danny_rico@icloud.com Nome: Danny Rico Data: 02/06/2021

Para corrigir isso, pode adicionar mais colunas à tabela para Nome, E-mail, Classificação e Data e, em seguida, usar EXTRAIR.REGEX para encontrar os dados que pretende e obtê-los como resultado na célula.

Por exemplo, pode introduzir a seguinte fórmula para obter um nome como resultado:

O editor de fórmulas a mostrar a fórmula =EXTRAIR.REGEX(A2,"(?<=Nome: )(.*)(?= Data)".

Nesta fórmula, são usados os seguintes argumentos:

cadeia-origem: A2, a célula com os dados que pretende para procurar um nome.
cadeia‑expressão‑regular: "(?<=Nome: )(.*)(?= Data)”, uma expressão regular que procura texto entre a cadeia “Nome: " e " Data".

Essa fórmula pode ser repetida em cada linha de dados para ter como resultado o nome de cada pessoa que respondeu ao inquérito alterando origem-cadeia para corresponder as outras células que contêm a informação da opinião do utilizador.

Por exemplo, pode introduzir a seguinte fórmula:

O editor de fórmulas a mostrar a fórmula =EXTRAIR.REGEX(A2,"[A-Z0-9a-z._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,4}")

Nesta fórmula, são usados os seguintes argumentos:

cadeia-origem: A2, a célula com os dados que pretende para procurar um e-mail.
cadeia‑expressão‑regular: "[A-Z0-9a-z._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,4}", uma expressão regular que procura o padrão de um endereço de e-mail.

Reorganizar dados de uma lista com ocorrência‑correspondência
Por vezes, pode ter dados como a tabela (com o título Fornecedores) abaixo, que agrupa valores numa célula:

Fornecedor	Artigo
A	Lentilhas, Grão-de-bico, Lima
B	Maçãs, Laranjas, Limões
C	Quinoa, Arroz, Chia

Para separar os valores com base na loja e classificação, pode primeiro criar uma nova tabela, tal como a tabela abaixo:

	A	B	C	D
1	Classificação	A	B	C
2	1
3	2
4	3

Para ter como resultado Lentilhas, o artigo com melhor classificação para o Fornecedor A, pode usar uma fórmula como esta na célula B2 da nova tabela para ter como resultado Lentilhas, o artigo com melhor classificação para o Fornecedor A:

O editor de fórmulas a mostrar a fórmula =EXTRAIR.REGEX(Fornecedores::B2,"\w+",LINHA(A2)-1).

Nesta fórmula, são usados os seguintes argumentos:

cadeia-origem: Fornecedores::B2, a célula com os dados que pretende para procurar. Neste caso, pretende procurar a lista nesta célula.
cadeia‑expressão‑regular: "\w+", uma expressão regular que procura por uma palavra.
ocorrência-correspondência: LINHA(A2)-1. Nesse caso, há 3 correspondências para cada EXTRAIR.REGEX e pode usar outra função, tal como LINHA, para definir uma correspondência específica que pretende. LINHA(A2) tem como resultado o número da linha da célula selecionada (2) e -1 é incluído para subtrair a linha de cabeçalho do resultado; caso contrário teria como resultado Grão-de-bico (a segunda correspondência) neste exemplo.
Se omitir ocorrência‑correspondência, o resultado para cada fornecedor é sempre a primeira palavra do resultado (Lentilhas para o Fornecedor A, Maçãs para o Fornecedor B, etc.).

A fórmula acima pode ser modificada para preencher a tabela para outros fornecedores e outros artigos.

Para ter como resultado outros produtos populares para um único fornecedor, pode modificar ocorrência‑correspondência. Por exemplo, para ter como resultado Grão-de-bico, o próximo artigo mais popular do Fornecedor A, pode alterar a referência da célula em ocorrência‑correspondência de A2 para A3.
Para ter como resultado valores de outro fornecedor, pode modificar origem-cadeia. Por exemplo, para ter como resultado Maçãs, o artigo mais popular do Fornecedor B, pode alterar a referência da célula em origem-cadeia de B2 para B3.

Exemplos adicionais
Permitir que A1 seja "marina@exemplo.com joel@example.ca miguel@example.de". =EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})") tem como resultado "marina@example.com". =EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2) tem como resultado "manuel@example.ca". =EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; -1) tem como resultado "miguelexample.de". =EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 1; 1) tem como resultado "marina". =EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2; 2) tem como resultado "example.ca".

Exemplos adicionais

Permitir que A1 seja "marina@exemplo.com joel@example.ca miguel@example.de".

=EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})") tem como resultado "marina@example.com".

=EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2) tem como resultado "manuel@example.ca".

=EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; -1) tem como resultado "miguelexample.de".

=EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 1; 1) tem como resultado "marina".

=EXTRAIR.REGEX(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2; 2) tem como resultado "example.ca".

Ver tambémREGEX

Útil?

Ajuda sobre fórmulas e funções

EXTRAIR.REGEX

Notas