SUMIF

SUMIF 函数返回数字集合的和，且仅包括满足指定条件的数字。

SUMIF(待检验的值, 条件, 待求和的值)

待检验的值： 集合，包含要测试的值。 待检验的值可以包含任何值。

条件： 比较或检验值，并返回布尔值 TRUE 或 FALSE 的表达式。条件可包括比较运算符、常数、与符号并置运算符、引用表达式和通配符。你可以使用通配符来匹配表达式中的任何单个字符或多个字符。你可以使用 ? （问号）表示一个字符，*（星号）表示多个字符，并使用 ~（波浪号）来指定下一个字符应当匹配，而非用作通配符。条件还可包含 REGEX 函数，而无需通配符。

待求和的值： 可选集合，含有要进行求和的值。 待求和的值可以包含数字值、日期/时间值或持续时间值。应该与待检验的值的大小相同。

注释

如果忽略待求和的值，默认值将为待检验的值。
尽管待检验的值可以包含任何值，但通常包含的值全都应该属于同一值类型。
如果忽略待求和的值，待检验的值通常仅含有数字或持续时间值。

示例
假设表格如下：

	A	B	C	D	E
1	1	10	a	a	c
2	2	20	b	c	b
3	3	30	a	a	c
4	4	40
5	5	50	1	5	9

=SUMIF(A1:A5, "<5") 返回 10，因为 1、2、3 和 4（条件的值小于 5，包含在待检验的值的范围 A1:A5 内）的和是 10。

=SUMIF(A1:A5, "<>4") 返回 11，因为 1、2、3 和 5（条件的值不等于 4，包含在待检验的值的范围 A1:A5 内）的和是 11。你也可以使用 ≠ 运算符。

=SUMIF(A1:A5, "<5", B1:B5) 返回 100，因为 10、20、30 和 40（A 列中小于 5 的值在 B 列（待求和的值 是 B1:B5）中所对应的值）的总和是 100。

=SUMIF(D1:E3, "=c", A3:B5) 返回 84，因为与待检验的值中等于“c”的单元格（单元格 E1、D2 和 E3）对应的待求和的值中的单元格（单元格 B3、A4 和 B5）包含 30、4 和 50，总和为 84。

=SUMIF(A1:D5, 1) 或 =SUMIF(A1:D5, SUM(1)) 各返回 2，即范围内所有出现的 1 的总和。

使用 REGEX 示例
假设表格如下：

	A	B
1	45	marina@cavanna.com
2	41	Aaron
3	29	michael@cavanna.com
4	64	katrina@example.com
5	12	Sarah

=SUMIF(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"),A1:A5) 返回 138，即 A1:A5 中对应单元格在 B1:B5 中包含电子邮件地址的单元格的总和。

另请参阅AVERAGEIF AVERAGEIFS SUMIFS SUM

有帮助?

公式与函数帮助

SUMIF

注释