NB.SI
La fonction NB.SI renvoie le nombre de cellules d’une collection qui remplissent une condition donnée.
NB.SI(tableau-test; condition)
tableau-test : Collection comportant les valeurs à tester. tableau-test peut contenir des valeurs quelconques.
condition : Une expression qui compare ou teste des valeurs et qui renvoie la valeur booléenne VRAI ou FAUX. Une condition peut comprendre des opérateurs de comparaison, des constantes, l’opérateur de concaténation esperluette, des références et des caractères génériques. Les caractères génériques permettent de faire correspondre un ou plusieurs caractères dans une expression. Vous pouvez utiliser ? (point d’interrogation) pour représenter un caractère, * (astérisque) pour représenter plusieurs caractères et ~ (tilde) pour indiquer que le caractère suivant doit être utilisé littéralement et non comme caractère générique. La condition peut également contenir une fonction REGEX plutôt que des caractères génériques.
Notes
Chaque valeur de tableau-test est comparée à la condition. Si elle satisfait au test conditionnel, la valeur est prise en compte pour la détermination du nombre renvoyé par la fonction.
Exemples |
|---|
Les informations contenues dans le tableau suivant n’ont pas de signification, mais elles illustrent le type d’arguments que NB.SI inclut dans ses résultats. Prenons le tableau suivant : |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | VRAI | VRAI | FAUX | FAUX |
5 | 200 | 400 |
=NB.SI(A1:D1; ">0") renvoie 4, car toutes les cellules de la collection ont une valeur supérieure à 0. =NB.SI(A1:D1; "<>100") renvoie 3, car trois cellules de la collection ont une valeur différente de 100. Vous pouvez aussi utiliser l’opérateur ≠. =NB.SI(A3:D3; ">=100") renvoie 3, car les trois nombres ont tous une valeur supérieure ou égale à 100 et que la valeur de texte est ignorée pour la comparaison. Vous pouvez aussi utiliser l’opérateur ≥. =NB.SI(A1:D5; "=ipsum") renvoie 1, car la chaîne de texte « ipsum » apparaît une fois dans la collection référencée par l’intervalle. =NB.SI(A1:D5; "=*t") renvoie 2, car une chaîne se terminant par la lettre « t » apparaît deux fois dans la collection référencée par l’intervalle. |
Exemple utilisant EXPREG |
|---|
Prenons le tableau suivant : |
A | B | |
|---|---|---|
1 | 45 | marie@example.com |
2 | 41 | Antoine |
3 | 29 | michael@example.com |
4 | 64 | catherine@example.com |
5 | 12 | Sarah |
=NB.SI(B1:B5; EXPREG("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) renvoie le nombre de cellules dans B1:B5 qui contiennent une adresse courriel. |
Exemple : résultats d’un sondage |
|---|
Cet exemple englobe toutes les illustrations utilisées dans les fonctions statistiques. Il est basé sur un sondage hypothétique. Le sondage est court (seulement cinq questions) et le nombre de personnes interrogées est très limité (10). La réponse à chaque question se situe sur une échelle de 1 à 5 (probablement de « jamais » à « toujours ») ou est laissée vierge. Un numéro (ID) a été attribué à chaque sondage avant d’être envoyé par courrier. Les tableaux suivants répertorient les résultats. Les questions dont les réponses sont incorrectes (hors de l’intervalle) ou qui sont restées sans réponses sont indiquées par une cellule noire dans le tableau. |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID | T1 | T2 | T3 | T4 | T5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Pour illustrer certaines des fonctions, supposons que le numéro du sondage comprenait un préfixe alphabétique et que l’échelle était de A à E, au lieu de 1 à 5. Le tableau ressemble alors à ce qui suit : |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID | T1 | T2 | T3 | T4 | T5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
En utilisant ce tableau de données et certaines des fonctions statistiques disponibles, vous pouvez collecter des informations sur les résultats du sondage. N’oubliez pas que l’exemple contient volontairement peu de données. Les résultats peuvent ainsi sembler évidents. Cependant, si le nombre des personnes interrogées atteignait 50, 100 ou plus, et si les questions étaient plus nombreuses, les résultats ne seraient pas évidents. |
Fonction et arguments | Description de résultat |
|---|---|
=COEFFICIENT.CORRELATION(B2:B11; C2:C11) | Détermine la corrélation entre la question 1 et la question 2 à l’aide de l’analyse de régression linéaire. Une corrélation est une mesure de la modification simultanée de près de deux variables (dans cet exemple, les réponses à des questions de sondage). De manière spécifique, elle étudie la question suivante : Si une personne interrogée a répondu à la question 1 par une valeur supérieure (ou inférieure) à la moyenne pour la question 1, a-t-elle également répondu à la question 2 par une valeur supérieure (ou inférieure) à la moyenne pour la question 2? Dans ce cas, les réponses ne sont pas particulièrement bien corrélées (-0,1732). |
=NB(A2:A11) ou =NBVAL(A2:A11) | Détermine le nombre total de sondages renvoyés (10). Notez que si le numéro de sondage n’est pas numérique, vous devez utiliser NBVAL au lieu de NB. |
=NB(B2:B11) ou =NBVAL(B2:B11) | Détermine le nombre total de réponses à la première question (9). En développant cette formule à travers la rangée, vous pouvez déterminer le nombre total de réponses à chaque question. Toutes les données sont numériques. Par conséquent, NBVAL renvoie les mêmes résultats. Cependant, si l’échelle utilisée pour le sondage était de A à E, au lieu de 1 à 5, vous devriez utiliser NBVAL pour calculer les résultats. |
=NB.VIDE(B2:B11) | Détermine le nombre de cellules vides, représentant des réponses non valides ou inexistantes. Si vous développez cette formule à travers la rangée, vous découvrez que la question 3 (colonne D) comporte 3 réponses non valides ou inexistantes. Cela peut vous conduire à examiner cette question du sondage pour déterminer si elle était douteuse ou mal rédigée, étant donné qu’aucune autre question n’a eu plus d’une réponse incorrecte ou inexistante. |
=NB.SI(B2:B11; "=5") | Détermine le nombre de personnes interrogées ayant donné une note de 5 à une question particulière (dans cet exemple, il s’agit de la question 1). Si vous développez cette formule à travers la rangée, vous découvrez que seules les questions 1 et 4 ont obtenu une note de 5 auprès des personnes interrogées. Si l’intervalle utilisé pour le sondage avait été de A à E, vous auriez dû utiliser =NB.SI(B2:B11; "=E"). |
=NB.SI(B2:B11; "<>5") | Détermine le nombre de personnes interrogées n’ayant pas donné une note de 5 à une question particulière (dans cet exemple, il s’agit de la question 1). |
=COVARIANCE(B2:B11; C2:C11) | Détermine la covariance des questions 1 et 2. La covariance est une mesure du niveau de la modification simultanée de deux variables (dans cet exemple, les réponses à des questions de sondage). De manière spécifique, elle étudie la question suivante : Si une personne interrogée a répondu à la question 1 par une valeur supérieure (ou inférieure) à la moyenne pour la question 1, a-t-elle également répondu à la question 2 par une valeur supérieure (ou inférieure) à la moyenne pour la question 2? Remarque : COVARIANCE ne fonctionne pas avec le tableau utilisant une échelle de A à E, étant donné que cette fonction demande des arguments numériques. |
=ECARTYPE(B2:B11) ou =ECARTYPEP(B2:B11) | Détermine l’écart-type, à savoir une mesure de la dispersion, des réponses à la question 1. Si vous développez cette formule à travers la rangée, vous découvrez que les réponses à la question 3 comprennent l’écart type le plus élevé. Si les résultats regroupaient les réponses de l’ensemble de la population étudiée, plutôt qu’un échantillon, il faudrait utiliser ECARTYPEP au lieu de ECARTYPE. Notez que ECARTYPE est la racine carrée de VAR. |
=VAR(B2:B11) ou =VAR.P(B2:B11) | Détermine la variance, à savoir une mesure de la dispersion, des réponses à la question 1. Si vous développez cette formule à travers la rangée, vous découvrez que les réponses à la question 5 comprennent l’écart type le plus faible. Si les résultats regroupaient les réponses de l’ensemble de la population étudiée, plutôt qu’un échantillon, il faudrait utiliser VAR.P au lieu de VAR. Notez que VAR est la racine carrée de ECARTYPE. |