CONTAR.SE
A função CONTAR.SE retorna a quantidade de células em uma coleção que satisfaz uma determinada condição.
CONTAR.SE(matriz teste; condição)
matriz teste: A coleção que contém os valores a serem testados. matriz teste pode conter quaisquer valores.
condição: Uma expressão que compara ou testa valores e resultados no valor booleano VERDADEIRO ou FALSO. condição pode incluir operadores de comparação, constantes, o operador de concatenação, referências e curingas. Você pode usar curingas para fazer coincidir qualquer caractere individual ou caracteres múltiplos em uma expressão. Você pode usar um ? (ponto de interrogação) para representar um caractere, um * (asterisco) para representar vários caracteres e um ~ (til) para especificar que o caractere seguinte deve ser correspondido, ao invés de usado como um curinga. condição também pode conter uma função EXPREG em vez de curingas.
Observações
Cada valor de matriz teste é comparado à condição. Se o valor satisfizer o teste condicional, é incluso na contagem.
Exemplos |
|---|
As informações na tabela a seguir não são significativas, mas são úteis para ilustrar os tipos de argumentos que a função CONTAR.SE inclui em seu resultado. Dada a tabela a seguir: |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | VERDADEIRO | VERDADEIRO | FALSO | FALSO |
5 | 200 | 400 |
=CONTAR.SE(A1:D1; ">0") retorna 4, já que todas as células na coleção possuem um valor maior que zero. =CONTAR.SE(A3:D3; ">=100") retorna 3, já que os três números são maiores ou iguais a 100 e o valor de texto é ignorado na comparação. =CONTAR.SE(A1:D5; "=ipsum") retorna 1, já que a string de teste “ipsum” aparece uma vez na coleção referida pelo intervalo. =CONTAR.SE(A1:D5; "=*t") retorna 2, já que uma string que termina com a letra “t” aparece duas vezes na coleção referida pelo intervalo. |
Exemplo usando EXPREG |
|---|
Dada a tabela a seguir: |
A | B | |
|---|---|---|
1 | 45 | jaime@appleseed.com |
2 | 41 | André |
3 | 29 | joanadantas@appleseed.com |
4 | 64 | jonas@appleseed.com |
5 | 12 | Sara |
=CONTAR.SE(B1:B5; EXPREG("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) retorna o número de células em B1:B5 que contêm um endereço de e-mail. |
Exemplo – resultados de pesquisas |
|---|
Este exemplo reúne as ilustrações usadas ao longo das funções estatísticas. É baseado em uma pesquisa hipotética. A pesquisa foi curta (somente cinco questões) e teve um número muito limitado de respondentes (10). Cada questão poderia ser respondida em uma escala de 1 a 5 (talvez o intervalo entre “nunca” e “sempre”) ou não respondida. A cada pesquisa foi atribuído um número (nº ID) antes do envio. A tabela seguinte mostra os resultados. Questões que foram respondidas fora do intervalo (incorretas) ou não respondidas estão indicadas com uma célula vazia na tabela. |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | nº ID | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Para ilustrar algumas das funções, suponha que o número da pesquisa incluiu um prefixo alfabético e que a escala foi de A–E, em vez de 1-5. Então, a tabela teria esta aparência: |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | nº ID | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Usando esta tabela de dados e algumas das funções estatísticas disponíveis, você pode colher informações sobre os resultados da pesquisa. Considere que o exemplo é pequeno propositalmente, então, os resultados podem parecer óbvios. Porém, se houvesse 50, 100 ou mais respondentes e, talvez, muito mais questões, os resultados não seriam óbvios. |
Função e argumentos | Descrição de resultado |
|---|---|
=CORREL(B2:B11; C2:C11) | Determina a correlação das questões 1 e 2 usando a análise de regressão linear. Correlação é uma medida de quanto duas variáveis (neste caso, respostas às questões da pesquisa) mudam juntas. Especificamente, isto apontaria para a pergunta: Se um respondente respondeu à questão 1 com um valor mais alto (ou baixo) que a média para a questão 1, será que o respondente também respondeu à questão 2 com um valor mais alto (ou baixo) que a média para a questão 2? Neste caso, as respostas não são particularmente bem correlatas (-0,1732). |
=CONTAR(A2:A11) ou =CONTAR.VAL(A2:A11) | Determina o número total de pesquisas retornadas (10). Observe que, se o número da pesquisa não fosse numérico, você precisaria usar CONTAR.VAL ou invés de CONTAR. |
=CONTAR(B2:B11) ou =CONTAR.VAL(B2:B11) | Determina o número total de respostas à primeira questão (9). Ao estender esta fórmula pela linha, você poderia determinar o número total de respostas à cada questão. Uma vez que todos os dados são numéricos, CONTAR.VAL retorna os mesmos resultados. Contudo, se a pesquisa tivesse usado de A até E em vez de 1 até 5, você teria que usar CONTAR.VAL para calcular os resultados. |
=CONTAR.VAZIO(B2:B11) | Determina a quantidade de células em branco, que representam respostas inválidas ou inexistentes. Se você estendesse essa fórmula ao longo da linha, você descobriria que a questão 3 (coluna D) teve 3 respostas inválidas ou não respondidas. Isto pode fazer com que você olhe para esta questão na pesquisa para verificar se é controversa ou se foi mal redigida, uma vez que nenhuma outra questão teve mais de 1 resposta incorreta ou não respondida. |
=CONTAR.SE(B2:B11; "=5") | Determina o número de respondentes que deram nota 5 a uma questão em particular (neste caso, a questão 1). Se você estendesse essa fórmula ao longo da linha, você descobriria que a somente as questões 1 e 4 tiveram nota 5 de qualquer respondente. Se a pesquisa tivesse usado de A até E como intervalo, você teria usado =CONTAR.SE(B2:B11; "=E"). |
=COVAR(B2:B11; C2:C11) | Determina a covariância das questões 1 e 2. Covariância é uma medida de quanto duas variáveis (neste caso, respostas às questões da pesquisa) mudam juntas. Especificamente, isto apontaria para a pergunta: Se um respondente respondeu à questão 1 com um valor mais alto (ou baixo) que a média para a questão 1, será que o respondente também respondeu à questão 2 com um valor mais alto (ou baixo) que a média para a questão 2? Observação: COVAR não funcionaria com a tabela com escala A - E, pois requer argumentos numéricos. |
=DESVPAD(B2:B11) ou =DESVPADP(B2:B11) | Determina o desvio padrão — uma medida de dispersão — das respostas à questão 1. Se você estendesse essa fórmula ao longo da linha, você descobriria que a questão 3 teve o padrão mais alto de desvio. Se os resultados representassem respostas de toda a população sendo estudada, em vez de uma amostra, DESVPADP seria usado em vez de DESVPAD. Observe que DESVPAD é a raiz quadrada de VAR. |
=VAR(B2:B11) ou =VARP(B2:B11) | Determina a variância — uma medida de dispersão — das respostas à questão 1. Se você estendesse essa fórmula ao longo da linha, você descobriria que as respostas à questão 5 tiveram a variância mais baixa. Se os resultados representassem respostas de toda a população sendo estudada, em vez de uma amostra, VARP seria usado em vez de VAR. Observe que VAR é a raiz quadrada de DESVPAD. |