![](https://help.apple.com/assets/5FA1D215680CE2131C638C37/5FA1D977680CE29611638C42/nl_NL/784be3dfed809d4b6bb7cc427d8c5f01.png)
AANTAL.ALS
De functie AANTAL.ALS retourneert het aantal cellen in een verzameling dat aan een opgegeven voorwaarde voldoet.
AANTAL.ALS(toetsmatrix; voorwaarde)
toetsmatrix: De verzameling met de waarden die moeten worden getoetst. toetsmatrix kan uit een willekeurige waarde bestaan.
voorwaarde: Een uitdrukking die waarden vergelijkt of test en die resulteert in de booleaanse waarde WAAR of ONWAAR. voorwaarde kan vergelijkingsoperatoren, constanten, de samenvoegingsoperator "&", verwijzingen en jokers bevatten. Je kunt jokers gebruiken om een of meer tekens in de uitdrukking te zoeken. Je kunt een ? (vraagteken) gebruiken om één teken te representeren, een * (asterisk) om meerdere tekens te representeren en het teken ~ (tilde) om aan te geven dat het daaropvolgende teken moet worden gezocht en niet als joker moet worden beschouwd. voorwaarde kan ook een REGEX-functie in plaats van jokers bevatten.
Opmerkingen
Elke toetsmatrix-waarde wordt vergeleken met voorwaarde. Als de waarde aan de voorwaarde voldoet, wordt de waarde opgenomen in de telling.
Voorbeelden |
---|
De gegevens in de volgende tabel hebben geen betekenis, maar geven wel duidelijk aan welke typen argumenten deel uitmaken van het resultaat van de functie AANTAL.ALS. Gegeven wordt de onderstaande tabel: |
A | B | C | D | |
---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | WAAR | WAAR | ONWAAR | ONWAAR |
5 | 200 | 400 |
=AANTAL.ALS(A1:D1; ">0") retourneert 4, omdat alle cellen in de verzameling een waarde bevatten die groter is dan nul. =AANTAL.ALS(A3:D3; ">=100") retourneert 3, omdat alle drie de getallen groter zijn dan of gelijk zijn aan 100 en de tekstwaarde in de vergelijking wordt genegeerd. =AANTAL.ALS(A1:D5; "=ipsum") retourneert 1, omdat de tekenreeks "ipsum" één keer voorkomt in de verzameling waarnaar het bereik verwijst. =AANTAL.ALS(A1:D5; "=*t") retourneert 2, omdat een tekenreeks die eindigt op de letter "t" twee keer voorkomt in de verzameling waarnaar het bereik verwijst. |
Voorbeeld met REGEX |
---|
Gegeven wordt de onderstaande tabel: |
A | B | |
---|---|---|
1 | 45 | john@appleseed.com |
2 | 41 | Aaron |
3 | 29 | janedoe@appleseed.com |
4 | 64 | jake@appleseed.com |
5 | 12 | Sarah |
=AANTAL.ALS(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) retourneert het aantal cellen in B1:B5 dat een e-mailadres bevat. |
Voorbeeld – Onderzoeksresultaten |
---|
Dit voorbeeld laat de toepassing van diverse statistische functies zien. Er wordt uitgegaan van een hypothetisch onderzoek. Het betreft een kort onderzoek (met slechts vijf vragen) en een zeer beperkt aantal respondenten (tien). Elke vraag kon worden beantwoord aan de hand van een schaal van 1 tot en met 5 (bijvoorbeeld variërend van "nooit" tot "altijd") of kon onbeantwoord worden gelaten. Elk onderzoek had een nummer (ID) gekregen voordat het werd uitgestuurd. In de volgende tabel staan de resultaten. Vragen die niet correct (buiten het bereik van de schaal) of niet waren beantwoord, worden in de tabel aangegeven met een lege cel. |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID | V1 | V2 | V3 | V4 | V5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Om enkele functies te illustreren, gaan we ervan uit dat het onderzoeksnummer werd voorafgegaan door een letter en dat de schaal niet van 1 tot en met 5, maar van A tot en met E liep. De tabel zou er dan als volgt uitzien: |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID | V1 | V2 | V3 | V4 | V5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Aan de hand van deze gegevenstabel en bepaalde beschikbare statistische functies kun je informatie over de onderzoeksresultaten vergaren. Het voorbeeld is bewust klein gehouden, zodat de resultaten duidelijk zijn. Met 50, 100 of meer respondenten en misschien veel meer vragen zou dat echter niet het geval zijn. |
Functie en argumenten | Beschrijving van het resultaat |
---|---|
=CORRELATIE(B2:B11; C2:C11) | Bepaalt de correlatie tussen vraag 1 en vraag 2 met behulp van lineaire regressie-analyse. Correlatie laat zien in welke mate twee variabelen (in dit geval antwoorden op onderzoeksvragen) elkaar beïnvloeden. Hiermee wordt met name naar de vraag gekeken: Als een respondent vraag 1 met een hogere (of lagere) waarde heeft beantwoord dan de gemiddelde waarde voor vraag 1, heeft de respondent dan ook vraag 2 met een hogere (of lagere) waarde beantwoord dan de gemiddelde waarde voor vraag 2? In dit geval is er geen sterke correlatie tussen de vragen (-0,1732). |
=AANTAL(A2:A11) of =AANTALARG(A2:A11) | Bepaalt het totale aantal teruggestuurde onderzoeken (10). Als het onderzoeksnummer niet numeriek was geweest, had je de functie AANTALARG in plaats van de functie AANTAL moeten gebruiken. |
=AANTAL(B2:B11) of =AANTALARG(B2:B11) | Bepaalt het totale aantal antwoorden op de eerste vraag (9). Door de formule ook in de rest van de rij in te voeren, kun je het totale aantal antwoorden op elke vraag bepalen. Aangezien alle gegevens numeriek zijn, retourneert de functie AANTALARG dezelfde resultaten. Als in het onderzoek echter met een schaal van A tot en met E in plaats van 1 tot en met 5 was gewerkt, zou je de resultaten met de functie AANTALARG moeten berekenen. |
=AANTALLEEG(B2:B11) | Bepaalt het aantal lege cellen, dat wil zeggen het aantal ongeldige of ontbrekende antwoorden. Als je deze formule ook in de rest van de rij zou invoeren, zou je zien dat op vraag 3 (kolom D) driemaal een ongeldig antwoord of geen antwoord is gegeven. Dit kan aanleiding zijn om na te gaan of de vraag controversieel of slecht geformuleerd was, aangezien bij geen van de andere vragen meer dan één incorrect of niet-gegeven antwoord voorkomt. |
=AANTAL.ALS(B2:B11; "=5") | Bepaalt het aantal respondenten dat een bepaalde vraag met een 5 heeft beantwoord (in dit geval vraag 1). Als je deze formule ook in de rest van de rij zou invoeren, zou je zien dat de respondenten alleen vraag 1 en vraag 4 met een 5 hebben beantwoord. Als in het onderzoek met een schaal van A tot en met E zou zijn gewerkt, zou je de formule =AANTAL.ALS(B2:B11; "=E") hebben moeten gebruiken. |
=COVARIANTIE(B2:B11; C2:C11) | Bepaalt de covariantie van vraag 1 en vraag 2. Covariantie laat zien in welke mate twee variabelen (in dit geval antwoorden op onderzoeksvragen) met elkaar samenhangen. Hiermee wordt met name naar de vraag gekeken: Als een respondent vraag 1 met een hogere (of lagere) waarde heeft beantwoord dan de gemiddelde waarde voor vraag 1, heeft de respondent dan ook vraag 2 met een hogere (of lagere) waarde beantwoord dan de gemiddelde waarde voor vraag 2? Opmerking: COVARIANTIE is niet geschikt voor een tabel waarin met een schaal van A tot en met E wordt gewerkt, aangezien bij deze functie numerieke argumenten moeten worden gebruikt. |
=STDEV(B2:B11) of =STDEVP(B2:B11) | Bepaalt de standaarddeviatie (een spreidingsmaat) van de antwoorden op vraag 1. Als je deze formule ook in de rest van de rij zou invoeren, zou je zien dat de antwoorden op vraag 3 de hoogste standaarddeviatie hadden. Als de resultaten de antwoorden van de gehele onderzochte populatie zouden voorstellen en niet van een steekproef, zou niet de functie STDEV, maar de functie STDEVP worden gebruikt. STDEV is de vierkantswortel van VAR. |
=VAR(B2:B11) of =VARP(B2:B11) | Bepaalt de variantie (een spreidingsmaat) van de antwoorden op vraag 1. Als je deze formule ook in de rest van de rij zou invoeren, zou je zien dat de antwoorden op vraag 5 de laagste variantie hebben. Als de resultaten de antwoorden van de gehele onderzochte populatie vertegenwoordigden en niet van een steekproef, zou niet de functie VAR, maar de functie VARP worden gebruikt. STDEV is het kwadraat van VAR. |