CONTA.SE
La funzione CONTA.SE restituisce il numero di celle di un insieme che soddisfano una determinata condizione.
CONTA.SE(matrice_test; condizione)
matrice_test: l'insieme che contiene i valori con cui effettuare il test. matrice_test può contenere qualsiasi tipo di valori.
condizione: un'espressione che confronta o testa valori e risultati del valore booleano VERO o FALSO. condizione che include operatori di confronto, costanti, l'operatore di concatenamento & (e commerciale), riferimenti e caratteri jolly. Puoi utilizzare i caratteri jolly per un singolo carattere o più caratteri in un'espressione. Puoi utilizzare un ? (punto interrogativo) per rappresentare un carattere, un * (asterisco) per rappresentare più caratteri e una ~ (tilde) per specificare che il carattere seguente deve corrispondere piuttosto che essere utilizzato come carattere jolly. condizione può anche contenere una funzione REGEX invece dei caratteri jolly.
Note
Ciascun valore di matrice_test viene messo a confronto con condizione. Se il valore soddisfa il test della condizione, viene incluso nel conteggio.
Esempi |
|---|
Le informazioni nella seguente tabella non sono significative, tuttavia sono utili per illustrare il tipo di argomenti che CONTA.SE include nel suo risultato. In base alla tabella seguente: |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | VERO | VERO | FALSO | FALSO |
5 | 200 | 400 |
=CONTA.SE(A1:D1; ">0") restituisce 4, poiché tutte le celle dell'insieme contengono un valore maggiore di zero. =CONTA.SE(A3:D3; ">=100") restituisce 3, poiché tutti e tre i numeri sono uguali o maggiori di 100 e il valore testo viene ignorato nel confronto. =CONTA.SE(A1:D5; "=ipsum") restituisce 1, poiché la stringa di test “ipsum” compare una volta nell'insieme definito dall'intervallo. =CONTA.SE(A1:D5; "=*t") restituisce 2, poiché nell'insieme definito dall'intervallo compare due volte una stringa che termina con la lettera t. |
Esempio di REGEX |
|---|
In base alla tabella seguente: |
A | B | |
|---|---|---|
1 | 45 | giovanni@appleseed.com |
2 | 41 | Alessandro |
3 | 29 | giuliarossi@appleseed.com |
4 | 64 | giacomo@appleseed.com |
5 | 12 | Sara |
=CONTA.SE(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) restituisce il numero di celle in B1:B5 che contengono un indirizzo e-mail. |
Esempio - Risultati sondaggio |
|---|
Questo esempio riunisce le illustrazioni utilizzate in tutte le funzioni statistiche. Si basa su un ipotetico sondaggio. Il sondaggio è breve (solo cinque domande) e ha un numero limitato di intervistati (10). Ogni domanda può ricevere una risposta su una scala da 1 a 5 (ad esempio l'intervallo da “mai” a “sempre”) oppure non ricevere risposta. Prima dell'invio, a ogni sondaggio è stato assegnato un numero (N. ID). La seguente tabella mostra i risultati. Le domande che hanno ricevuto risposte fuori dall'intervallo (non corrette) o che non hanno ricevuto risposta vengono indicate con una cella vuota nella tabella. |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | N. ID | T1 | T2 | T3 | T4 | T5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Per illustrare alcune delle funzioni, supponi che il numero del sondaggio includa un prefisso alfabetico e che la scala sia A–E invece che 1–5. La tabella apparirebbe così: |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | N. ID | T1 | T2 | T3 | T4 | T5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Utilizzando questa tabella di dati e alcune delle funzioni statistiche disponibili, puoi raccogliere le informazioni sui risultati del sondaggio. Tieni presente che l'esempio è volutamente di piccole dimensioni, quindi i risultati potrebbero sembrare ovvi. Ad ogni modo, se avessi 50, 100 o più intervistati e magari molte più domande, i risultati non sarebbero ovvi. |
Funzioni e argomenti | Descrizione del risultato |
|---|---|
=CORRELAZIONE(B2:B11; C2:C11) | Determina la correlazione della domanda 1 e della domanda 2 utilizzando l'analisi della regressione lineare. La correlazione è la misura di quanto si modificano insieme due variabili (in questo caso, le risposte alle domande del sondaggio). In modo specifico, questo risponde alla domanda: Se un intervistato ha risposto alla domanda 1 con una valore maggiore (o minore) della media per la domanda 1, lo stesso intervistato ha risposto anche alla domanda 2 con un valore maggiore (o minore) della media per la domanda 2? In questo caso, le risposte non sono particolarmente correlati (-0,1732) |
=CONTA.NUMERI(A2:A11) oppure =CONTA.VALORI(A2:A11) | Determina il numero totale di sondaggi tornati (10). Nota che se il numero del sondaggio non fosse numerico, dovresti usare CONTA.VALORI invece di CONTA.NUMERI. |
=CONTA.NUMERI(B2:B11) or =CONTA.VALORI(B2:B11) | Determina il numero totale di risposte alla prima domanda (9). Estendendo questa formula lungo la riga, potresti determinare il numero totale di risposte a ogni domanda. Siccome tutti i dati sono numerici, CONTA.VALORI restituisce lo stesso risultato. Se, comunque, il sondaggio ha usato da A a E, invece che da 1 a 5, dovrai usare CONTA-VALORI per fare coincidere i risultati. |
=CONTA.VUOTE(B2:B11) | Determina il numero di celle vuote, che rappresentano risposte non valide o non-risposte. Se estendi questa formula lungo la riga troverai che la domanda 3 (colonna D) ha ricevuto 3 risposte errate o non-risposte. Questo potrebbe portarti a controllare questa domanda sul sondaggio per vedere se era controversa o mal formulata, perché nessun altra domanda ha avuto più di 1 risposta errata o non-risposta. |
=CONTA.SE(B2:B11; "=5") | Determina il numero di intervistati che hanno risposto 5 a una particolare domanda (in questo caso, la domanda 1). Se estendi questa formula lungo la riga, scoprirai che solo le domande 1 e 4 hanno avuto intervistati che hanno risposto 5. Se il sondaggio usasse da A a E per l'intervallo, dovresti usare =CONTA.SE(B2:B11; "=E"). |
=COVARIANZA(B2:B11; C2:C11) | Determina la covarianza della domanda 1 e della domanda 2. La covarianza è la misura di quanto si modificano insieme due variabili (in questo caso, le risposte alle domande del sondaggio). In modo specifico, questo risponde alla domanda: Se un intervistato ha risposto alla domanda 1 con una valore maggiore (o minore) della media per la domanda 1, lo stesso intervistato ha risposto anche alla domanda 2 con un valore maggiore (o minore) della media per la domanda 2? Nota: COVARIANZA non funzionerebbe se la tabella utilizzasse una scala A–E, perché sono richiesti degli argomenti numerici. |
=DEV.ST(B2:B11) oppure =DEV.ST.POP(B2:B11) | Determina la deviazione standard, una misura della dispersione, delle risposte alla domanda 1. Se estendi questa formula lungo la riga, scoprirai che le riposte alla domanda 3 hanno avuto la deviazione standard maggiore. Se i risultati rappresentassero le risposte dall'intera popolazione studiata, invece che un campione, invece di DEV.ST useresti DEV.ST.POP. Nota che DEV.ST è la radice quadrata di VAR. |
=VAR(B2:B11) oppure =VAR.POP(B2:B11) | Determina la varianza, una misura della dispersione, delle risposte alla domanda 1. Se estendi questa formula lungo la riga, scoprirai che le riposte alla domanda 5 hanno avuto la varianza minore. Se i risultati rappresentassero le risposte dall'intera popolazione studiata, invece che un campione, invece di VAR useresti VAR.POP. Nota che VAR è il quadrato di DEV.ST. |