![](https://help.apple.com/assets/626C4EEE69937F618B403B14/626C4EF369937F618B403B34/hr_HR/784be3dfed809d4b6bb7cc427d8c5f01.png)
COUNTIF
Funkcija COUNTIF vraća broj ćelija u zbirci koje zadovoljavaju zadani uvjet.
COUNTIF(test-polje, uvjet)
test-polje: Zbirka koja sadrži vrijednosti za testiranje. test-polje može sadržavati bilo koju vrijednost.
uvjet: Izraz koji uspoređuje ili testira vrijednosti i rezultira booleovom vrijednosti TRUE ili FALSE. uvjet može uključivati operatore za usporedbu, konstante, operatora za ulančavanje, reference i zamjenske znakove. Možete koristiti zamjenske znakove koji će označavati bilo koji znak ili više znakova u izrazu. Možete upotrijebiti ? (upitnik) za predstavljanje jednog znaka, * (zvjezdicu) za predstavljanje više znakova i ~ (tildu) kako biste odredili da sljedeći znak treba biti usklađen umjesto da bude korišten kao zamjenski znak. uvjet može sadržavati i funkciju REGEX umjesto zamjenskih znakova.
Napomene
Svaka vrijednost test-polja uspoređuje se s uvjetom. Ako vrijednost zadovoljava uvjetni test, uključuje se u brojanje.
Primjeri |
---|
Informacije u sljedećoj tablici nemaju nikakvo značenje, ali su korisne kao primjer vrste argumenata koje COUNTIF uključuje u svoje rezultate. U sljedećoj tablici: |
A | B | C | D | |
---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | TRUE | TRUE | FALSE | FALSE |
5 | 200 | 400 |
=COUNTIF(A1:D1; ">0") vraća 4 zato što sve ćelije u zbirci imaju vrijednost veću od 0. =COUNTIF(A1:D1; "<>100") vraća 3 zato što sve ćelije u zbirci imaju vrijednost veću od nule. Također možete koristiti operator ≠ =COUNTIF(A3:D3; ">=100") vraća 3 zato što su sva tri broja veća ili jednaka 100, a tekstualna vrijednost se u usporedbi zanemaruje. Također možete koristiti operator ≥. =COUNTIF(A1:D5; "=ipsum") vraća 1 zato što se tekstualni niz "ipsum" pojavljuje samo jednom u zbirci na koju se referira raspon. =COUNTIF(A1:D5; "=*t") vraća 2 zato što se niz koji završava slovom "t" pojavljuje dvaput u zbirci na koju se referira raspon. |
Primjer u kojem se upotrebljava REGEX |
---|
U sljedećoj tablici: |
A | B | |
---|---|---|
1 | 45 | marina@primjer.com |
2 | 41 | Aaron |
3 | 29 | ivan@primjer.com |
4 | 64 | katarina@primjer.com |
5 | 12 | Sarah |
=COUNTIF(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) vraća broj ćelija u B1:B5 koje sadrže e-mail adresu. |
Primjer—Rezultati ankete |
---|
Ovaj primjer spaja ilustracije koje su korištene u statističkim funkcijama. Temelji se na hipotetskoj anketi. Anketa je bila kratka (samo pet pitanja) i imala je vrlo ograničen broj ispitanika (10). Odgovori na svako pitanje davali su se na skali od 1 do 5 (eventualno u rasponu od "nikad" do "uvijek"), a mogli su se i ostaviti praznima. Svakoj anketi dodijeljen je broj (ID#) prije slanja. Sljedeća tablica prikazuje rezultate. Pitanja na koja je odgovoreno izvan raspona (neispravno) ili na koja nije odgovoreno označena su s praznom ćelijom u tablici. |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Za ilustraciju nekih funkcija pretpostavite da je broj ankete imao slovni prefiks i da je skala bila od A do E, umjesto od 1 do 5. Tada bi tablica izgledala ovako: |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Uporabom ove tablice s podacima i nekih dostupnih statističkih funkcija možete prikupiti informacije o rezultatima ankete. Imajte na umu da je primjer namjerno malen pa se rezultati možda čine očitima. Međutim, ako biste imali 50, 100 ili više ispitanika i eventualno puno više pitanja rezultati ne bi bili očiti. |
Funkcija i argumenti | Opis rezultata |
---|---|
=CORREL(B2:B11; C2:C11) | Određuje korelaciju pitanja 1 i pitanja 2 uporabom linearne regresijske analize. Korelacija je mjera koja pokazuje koliko se dvije varijable (u ovom slučaju, odgovori na pitanja iz ankete) zajedno mijenjaju. Točnije, to uzima u obzir pitanje: Ako je ispitanik odgovorio na pitanje 1 s višom (ili nižom) vrijednosti od prosjeka za pitanje 1, je li ispitanik također odgovorio na pitanje 2 s višom (ili nižom) vrijednosti od prosjeka za pitanje 2? U tom slučaju, odgovori nisu baš dobro korelirani (-0.1732) |
=COUNT(A2:A11) ili =COUNTA(A2:A11) | Određuje ukupan broj vraćenih anketa (10). Imajte na umu da biste u slučaju da broj ankete nije bio brojčani trebali upotrijebiti COUNTA umjesto COUNT. |
=COUNT(B2:B11) ili =COUNTA(B2:B11) | Određuje ukupan broj odgovora na prvo pitanje (9). Ako biste proširili ovu formulu na cijeli redak, mogli biste odrediti ukupan broj odgovora na svako pitanje. S obzirom da su svi podaci brojčani, COUNTA vraća iste rezultate. Međutim, da ste u anketi upotrijebili skalu od A do E, umjesto od 1 do 5, trebali biste upotrijebiti COUNTA za izračun rezultata. |
=COUNTBLANK(B2:B11) | Određuje broj praznih ćelija, koje predstavljaju nevažeće odgovore ili pitanja bez odgovora, Kada biste proširili formulu preko retka otkrili biste da za pitanje 3 (stupac D) postoje 3 nevažeća odgovora ili odgovora nema. Zbog toga biste mogli pogledati to pitanje na anketi kako biste provjerili je li sporno ili loše sročeno, s obzirom da nijedno drugo pitanje nije imalo više od jednog neispravnoga odgovora niti je više od jednog ispitanika ostavilo ostala pitanja bez odgovora. |
=COUNTIF(B2:B11; "=5") | Određuje broj ispitanika koji su odabrali 5 na određenom pitanju (u ovom slučaju, pitanje 1). Kada biste proširili formulu preko retka otkrili biste da su samo za pitanja 1 i 4 neki ispitanici odabrali 5. Da se u anketi upotrebljavao raspon od A do E, upotrijebili biste =COUNTIF(B2:B11; "=E"). |
=COUNTIF(B2:B11; "<>5") | Određuje broj ispitanika koji nisu odabrali 5 na određenom pitanju (u ovom slučaju, pitanje 1). |
=COVAR(B2:B11; C2:C11) | Određuje kovarijancu pitanja 1 i pitanja 2. Kovarijanca je mjera koja pokazuje koliko se dvije varijable (u ovom slučaju, odgovori na pitanja iz ankete) zajedno mijenjaju. Točnije, to uzima u obzir pitanje: Ako je ispitanik odgovorio na pitanje 1 s višom (ili nižom) vrijednosti od prosjeka za pitanje 1, je li ispitanik također odgovorio na pitanje 2 s višom (ili nižom) vrijednosti od prosjeka za pitanje 2? Napomena: COVAR ne radi s tablicom koja koristi skalu A–E jer zahtijeva brojčane argumente. |
=STDEV(B2:B11) ili =STDEVP(B2:B11) | Određuje standardnu devijaciju—jednu mjeru disperzije—odgovora na pitanje 1. Kada biste proširili formulu preko retka otkrili biste da odgovori na pitanje 3 imaju najveću standardnu devijaciju. Ako rezultati predstavljaju odgovore cijele ispitivane populacije, a ne uzorka, koristila bi se funkcija STDEVP umjesto STDEV. Imajte na umu da je STDEV kvadratni korijen funkcije VAR. |
=VAR(B2:B11) ili =VARP(B2:B11) | Određuje varijancu—jednu mjeru disperzije—odgovora na pitanje 1. Kada biste proširili formulu preko retka otkrili biste da odgovori na pitanje 5 imaju najmanju varijancu. Ako rezultati predstavljaju odgovore cijele ispitivane populacije, a ne uzorka, koristila bi se funkcija VARP umjesto VAR. Imajte na umu da je funkcija VAR je kvadrat funkcije STDEV. |