COMPTAR.SI
La funció COMPTAR.SI calcula el nombre de cel·les d’un conjunt que compleixen una condició especificada.
COMPTAR.SI(matriu-prova; condició)
matriu-prova: el conjunt que conté els valors que s’avaluaran. matriu-prova pot contenir qualsevol valor.
condició: una expressió que compara o prova els valors i resultats en el valor booleà CERT o FALS. Una condició pot incloure operadors de comparació, constants, l’operador de concatenació et, referències i comodins. Pots utilitzar comodins per fer coincidir qualsevol caràcter únic o múltiple en l’expressió. Pots utilitzar un interrogant (?) per representar un caràcter, un asterisc (*) per representar diversos caràcters i una titlla (~) per especificar que el caràcter següent ha de ser coincident, en comptes d’usar-se com a comodí. La condició també pot contenir una funció REGEX en lloc de comodins.
Notes
Cada valor de matriu-prova es compara amb condició. Si el valor satisfà la prova condicional, s’inclou en el recompte.
Exemples |
|---|
La informació de la taula següent no és rellevant, però resulta útil per il·lustrar el tipus d’arguments que COMPTAR.SI inclou en el resultat. Donada la taula següent: |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | CERT | CERT | FALS | FALS |
5 | 200 | 400 |
=COMPTAR.SI(A1:D1; ">0") dona 4 perquè totes les cel·les del conjunt contenen un valor més gran que 0. =COMPTAR.SI(A1:D1; "<>100") dona 3 perquè tres les cel·les del conjunt contenen un valor diferent de 100. També pots utilitzar l’operador ≠. =COMPTAR.SI(A3:D3; ">=100") dona 3 perquè tots tres números són més grans o iguals que 100 i el valor de text s’ignora en la comparació. També pots utilitzar l’operador ≥. =COMPTAR.SI(A1:D5; "=ipsum") dona 1 perquè la cadena de text "ipsum" apareix una vegada en el conjunt referenciat per l’interval. =COMPTAR.SI(A1:D5; "=*t") dona 2 perquè hi ha una cadena acabada en la lletra t que apareix dues vegades en el conjunt referenciat per l’interval. |
Exemples amb REGEX |
|---|
Donada la taula següent: |
A | B | |
|---|---|---|
1 | 45 | marina@exemple.com |
2 | 41 | Albert |
3 | 29 | miquel@exemple.com |
4 | 64 | celia@exemple.com |
5 | 12 | Sara |
=COMPTAR.SI(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) dona el nombre de cel·les de l’interval B1:B5 que contenen una adreça de correu electrònic. |
Exemple (resultats de l’enquesta) |
|---|
Aquest exemple recull les mostres utilitzades en el conjunt de funcions estadístiques. Es basa en una enquesta hipotètica. És una enquesta curta (només cinc preguntes), amb un nombre molt limitat d’enquestats (10). Cadascuna de les preguntes s’ha respost en una escala de l’1 al 5 (que podria ser l’interval de "mai" a "sempre") o no s’ha respost. A cada enquesta se li va assignar un número (ID#) abans d’enviar-lo. A la taula següent se’n mostren els resultats. Les preguntes contestades fora de l’interval (incorrectes) o no contestades s’indiquen amb una cel·la en blanc a la taula. |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID# | 1T | 2T | 3T | 4T | Q5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Per il·lustrar algunes de les funcions, suposem que el número de l’enquesta incloïa un prefix alfabètic i que l’escala era A-E, en comptes d’1-5. La taula tindria aquest aspecte: |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID# | 1T | 2T | 3T | 4T | Q5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Utilitzant aquesta taula de dades i alguna de les funcions estadístiques disponibles, pots recopilar informació sobre el resultat de l’enquesta. Recorda que l’exemple és volgudament reduït, de manera que els resultats poden semblar molt obvis. Però si tinguéssim 50, 100 o més enquestats i potser també més preguntes, els resultats no serien tan obvis. |
Funció i arguments | Descripció del resultat |
|---|---|
=CORRELACIÓ(B2:B11;C2:C11) | Determina la correlació de la pregunta 1 i la pregunta 2 utilitzant l’anàlisi de regressió lineal. La correlació és una mesura de la quantitat amb què dues variables (en aquest cas respostes a una enquesta) canvien juntes. Concretament, miraria de la pregunta: Si un enquestat ha contestat a la pregunta 1 amb un valor més alt (o més baix) que la mitjana de la pregunta 1, també ha contestat a la pregunta 2 amb un valor més alt (o més baix) que la mitjana de la pregunta 2? En aquest cas, les respostes no tenen una correlació particular (-0,1732) |
=COMPTAR(A2:A11) o =COMPTAR.A(A2:A11) | Determina el nombre total d’enquestes trobades (10). Recorda que si el número de l’enquesta no és numèric hauràs d’utilitzar COMPTAR.A en comptes de COMPTAR. |
=COMPTAR(B2:B11) o =COMPTAR.A(B2:B11) | Determina el nombre total de respostes a la primera pregunta (9). Si estens aquesta fórmula al llarg de la fila, pots determinar el nombre total de respostes a cada pregunta. Com que totes les dades són numèriques, COMPTAR.A dona els mateixos resultats. Si en canvi l’enquesta hagués utilitzat d’A a E, en comptes d’1 a 5, hauries d’utilitzar COMPTAR.A per comptar els resultats. |
=COMPTAR.BUIDES(B2:B11) | Determina el nombre de cel·les buides, que representen respostes no vàlides o no contestades. Si estens aquesta fórmula al llarg de la fila, veuràs que la pregunta 3 (columna D) té 3 respostes no vàlides o no contestades. Això et pot fer valorar si aquesta pregunta de l’enquesta és controvertida o si està mal redactada, perquè no hi ha cap altra pregunta que tingui més d’una resposta no contestada o incorrecta. |
=COMPTAR.SI(B2:B11, "=5") | Determina el nombre d’enquestats que han contestat un 5 a una pregunta determinada (en aquest cas, la pregunta 1). Si estens la fórmula al llarg de la fila, podràs veure que només a les preguntes 1 i 4 hi ha enquestats que hagin contestat un 5. Si en l’enquesta s’hagués utilitzat l’interval de la A a la E, hauries d’haver utilitzat =COMPTAR.S(B2:B11, "=E"). |
=COMPTAR.SI(B2:B11; "<>5") | Determina el nombre d’enquestats que no han contestat un 5 a una pregunta determinada (en aquest cas, la pregunta 1). |
=COVAR(B2:B11;C2:C11) | Determina la covariància de la pregunta 1 i la pregunta 2. La covariància és una mesura de la quantitat amb què dues variables (en aquest cas respostes a una enquesta) canvien juntes. Concretament, miraria de la pregunta: Si un enquestat ha contestat a la pregunta 1 amb un valor més alt (o més baix) que la mitjana de la pregunta 1, també ha contestat a la pregunta 2 amb un valor més alt (o més baix) que la mitjana de la pregunta 2? Nota: COVAR no funcionaria amb la taula que utilitza l’escala de la A a la E, perquè necessita arguments numèrics. |
=DESV.ESTÀND(B2:B11) o =DESV.ESTÀND.P(B2:B11) | Determina la desviació estàndard (una mesura de dispersió) de les respostes a la pregunta 1. Si estens la fórmula al llarg de la fila, veuràs que les respostes a la pregunta 3 tenen la desviació estàndard més alta. Si els resultats representessin respostes de tota la població en estudi, i no una mostra, s’utilitzaria DESV.ESTÀND.P en comptes de DESV.ESTÀND. Recorda que DESV.ESTÀND és l’arrel quadrada de VAR. |
=VAR(B2:B11) o =VAR.P(B2:B11) | Determina la variància (una mesura de dispersió) de les respostes a la pregunta 1. Si estens la fórmula al llarg de la fila, veuràs que les respostes a la pregunta 5 tenen la variància més baixa. Si els resultats representessin respostes de tota la població en estudi, i no una mostra, s’utilitzaria VAR.P en comptes de VAR. Recorda que VAR és el quadrat de DESV.ESTÀND. |