IFS

IFS 函數根據評估為布林值 TRUE 的首個條件檢查指定表示式並傳回一個值。

IFS(ifs 表示式, ifs-true, ifs 表示式⋯, ifs-true⋯)

ifs 表示式： 邏輯表示式。 ifs 表示式可以包含任何內容，只要表示式可以評估為布林值。如果將表示式評估為數值，則會將 0 視同為 FALSE，而其他任何數值將視為 TRUE。

ifs-true： 若 ifs 表示式為 TRUE 時所傳回的數值。 ifs-true 可以包含任何值。若省略 ifs-true，（有逗號，但無值）且 ifs 表示式評估為 TRUE，則 IFS 會傳回 0。

ifs 表示式⋯： 若 ifs 表示式為 FALSE 時所評估的邏輯表示式（可留空）。 ifs 表示式可以包含任何內容，只要表示式可以評估為布林值。如果將表示式評估為數值，則會將 0 視同為 FALSE，而其他任何數值將視為 TRUE。

ifs-true⋯： 若 ifs 表示式⋯為 TRUE 時所傳回的數值。 ifs-true 可以包含任何值。若省略 ifs-true⋯，（有逗號，但無值）且 ifs 表示式⋯評估為 TRUE，則 IFS 會傳回 0。

附註

若所有表示式皆為 FALSE，則會傳回錯誤。
你可以在公式中為上一個 ifs 表示式⋯輸入「TRUE」，接著為 ifs-true⋯輸入預設值，以在之前所有的表示式（包含 ifs 表示式和所有 ifs 表示式⋯的實例）評估為 FALSE 時指定結果。

使用 IFS 進行多項比較
下表顯示學生成績列表。

	A	B	C
1	學生	分數	喜好程度
2	1	4	傑出
3	2	2	初階
4	3	3	精通
5	4		未完成
6	5	3.2	精通+
7	6	3.2	新手

下表使用多個 ifs 表示式⋯ 引數，傳回與上表中分數相關聯的評等。

「公式編輯器」顯示公式 =IFS(B2=4,"傑出",B2=3,"精通",B2=2,"初階",B2=1,"新手")。

這個公式中使用了以下引數：

ifs 表示式：B2=4，檢查 B2 是否等於 4。
ifs-true："傑出"，如果 B2 等於 4，便會傳回此字串。
ifs 表示式⋯："B2=3"，檢查 B2 是否等於 3。
ifs-true⋯："精通"，如果 B2 等於 3，便會傳回此字串。
ifs 表示式⋯："B2=2"，檢查 B2 是否等於 2。
ifs-true⋯："初階"，如果 B2 等於 2，便會傳回此字串。
ifs 表示式⋯："B2=1"，檢查 B2 是否等於 1。
ifs-true⋯："新手"，如果 B2 等於 1，便會傳回此字串。

若要搭配表格中的其他輸入格使用上方公式，請將每個條件表示式中的 B2 更改為包含分數的其他輸入格。

將 TRUE 用於 ifs 表示式⋯
有時如果沒有表示式評估為 TRUE，而是傳回錯誤，你可以在最終 ifs 表示式中設定傳回的字串。在上表中，學生 4 沒有分數，因此上一個公式針對該學生傳回了錯誤。也許這名學生當時缺席，所以仍需完成作業，因此不應顯示為錯誤，你可以加入另一個 ifs 表示式，將缺少的分數標示為「未完成」：在此範例中，更改了輸入格參照以符合學生 4 的分數輸入格，但所有引數都和上方相同，且於結尾再加上一個 ifs 表示式： ifs 表示式⋯：TRUE，加入為最後一個表示式。 ifs-true⋯："未完成"，如果沒有其他引數評估為 TRUE，則傳回此字串。

將 TRUE 用於 ifs 表示式⋯

有時如果沒有表示式評估為 TRUE，而是傳回錯誤，你可以在最終 ifs 表示式中設定傳回的字串。在上表中，學生 4 沒有分數，因此上一個公式針對該學生傳回了錯誤。也許這名學生當時缺席，所以仍需完成作業，因此不應顯示為錯誤，你可以加入另一個 ifs 表示式，將缺少的分數標示為「未完成」：

「公式編輯器」顯示公式 =IFS(B5=4,"傑出",B5=3,"精通",B5=2,"初階+",B5=1,"新手",TRUE,"未完成")。

在此範例中，更改了輸入格參照以符合學生 4 的分數輸入格，但所有引數都和上方相同，且於結尾再加上一個 ifs 表示式：

ifs 表示式⋯：TRUE，加入為最後一個表示式。
ifs-true⋯："未完成"，如果沒有其他引數評估為 TRUE，則傳回此字串。

較複雜的比較
某些情況下，你可能需要較複雜的表示式，用來混合使用比較運算子。例如，上方量表使用完整數字，但另一名學生（學生 6）的分數為 3.2。你可以使用類似下方的公式，為分數介於四個主要平等之間的學生（B6 為 3.2，學生 5 的分數）進行計算：在此範例中，在「傑出」、「精通」、「初階」和「新手」評等之間加入了另一個 ifs 表示式⋯ 引數。 ifs 表示式⋯："B6>3"，檢查 B6 是否大於 3。 ifs-true⋯："精通+"，如果 B2 大於 3，便會傳回此字串。 ifs 表示式⋯："B6>2"，檢查 B6 是否大於 2。 ifs-true⋯："初階+"，如果 B2 大於 2，便會傳回此字串。 ifs 表示式⋯："B6>1"，檢查 B6 是否大於 1。 ifs-true⋯："新手+"，如果 B2 大於 1，便會傳回此字串。 IFS 會尋找第一個 TRUE 表示式，因此這個公式行得通。如果學生的分數不是 4，IFS 會檢查分數是否大於 3；學生 5 的評等會是「精通+」。另一個範例是分數 2.5 的學生評等會為「初階+」，因為其分數不是 4、大於 3 也不是 3，但是大於 2。

較複雜的比較

某些情況下，你可能需要較複雜的表示式，用來混合使用比較運算子。例如，上方量表使用完整數字，但另一名學生（學生 6）的分數為 3.2。你可以使用類似下方的公式，為分數介於四個主要平等之間的學生（B6 為 3.2，學生 5 的分數）進行計算：

「公式編輯器」顯示公式 =IFS(B6=4,"傑出", B6>3, "精通+",B6=3,"精通",B6>2,"初階+",B6=2,"初階",B6>1,"新手+",B5=1,"新手",TRUE,"未完成")。

在此範例中，在「傑出」、「精通」、「初階」和「新手」評等之間加入了另一個 ifs 表示式⋯ 引數。

ifs 表示式⋯："B6>3"，檢查 B6 是否大於 3。
ifs-true⋯："精通+"，如果 B2 大於 3，便會傳回此字串。
ifs 表示式⋯："B6>2"，檢查 B6 是否大於 2。
ifs-true⋯："初階+"，如果 B2 大於 2，便會傳回此字串。
ifs 表示式⋯："B6>1"，檢查 B6 是否大於 1。
ifs-true⋯："新手+"，如果 B2 大於 1，便會傳回此字串。

IFS 會尋找第一個 TRUE 表示式，因此這個公式行得通。如果學生的分數不是 4，IFS 會檢查分數是否大於 3；學生 5 的評等會是「精通+」。另一個範例是分數 2.5 的學生評等會為「初階+」，因為其分數不是 4、大於 3 也不是 3，但是大於 2。

搭配其他函數使用 IFS
IFS 可搭配其他函數使用。例如，此函數使用 MOD 來判斷輸入格 A2 中的年份（此範例中為 A2=2020）是否為閏年：若要決定兩個值是否不相等，請使用比較運算子 <>。

搭配其他函數使用 IFS

IFS 可搭配其他函數使用。例如，此函數使用 MOD 來判斷輸入格 A2 中的年份（此範例中為 A2=2020）是否為閏年：

「公式編輯器」顯示公式 =IFS(MOD($A2,4)≠0 ,FALSE,MOD($A2,100)≠0,TRUE,MOD($A2,400)≠0,FALSE, TRUE, TRUE)。

若要決定兩個值是否不相等，請使用比較運算子 <>。

其他範例
=IFS(A2>91,"A",A2>82,"B",A2>73,"C",A2>64,"D",TRUE,"F") 會對大於 91 的數字傳回字母等級「A」，然後對大於 82 但小於 92 的數字傳回「B」，以此類推對所有小於 65 的數值傳回「F」。 =IFS(A2>91,"A",A2>82,"B",A2>73,"C",A2>64,"D",A2<>0,"已應試", "TRUE,"不及格") 會對大於 91 的數字傳回等第「A」，然後對大於 82 但小於 92 的數字傳回「B」，以此類推對所有小於 65 但不等於 0 的數值傳回「已應試」。如果分數是 0，則公式會傳回「不及格」。讓 A2 包含 "A dog" 讓 A1 = COUNTMATCHES(A2, REGEX("\w+")) =IFS(A1 = 0, "No word", A1 = 1, "One word", A1 = 2, "Two words", A1 > 2, "Multiple words") 會傳回 "Two words"。

其他範例

=IFS(A2>91,"A",A2>82,"B",A2>73,"C",A2>64,"D",TRUE,"F") 會對大於 91 的數字傳回字母等級「A」，然後對大於 82 但小於 92 的數字傳回「B」，以此類推對所有小於 65 的數值傳回「F」。

=IFS(A2>91,"A",A2>82,"B",A2>73,"C",A2>64,"D",A2<>0,"已應試", "TRUE,"不及格") 會對大於 91 的數字傳回等第「A」，然後對大於 82 但小於 92 的數字傳回「B」，以此類推對所有小於 65 但不等於 0 的數值傳回「已應試」。如果分數是 0，則公式會傳回「不及格」。

讓 A2 包含 "A dog"

讓 A1 = COUNTMATCHES(A2, REGEX("\w+"))

=IFS(A1 = 0, "No word", A1 = 1, "One word", A1 = 2, "Two words", A1 > 2, "Multiple words") 會傳回 "Two words"。

也請參閱AND IF NOT OR

有幫助？

公式與函數輔助說明

IFS

附註