HVIS.SETT

HVIS.SETT-funksjonen kontrollerer spesifiserte uttrykk og returnerer en verdi basert på den første betingelsen som evaluerer til den boolske verdien SANN.

HVIS.SETT(hvis.sett-uttrykk; hvis.sett-sann; hvis.sett-uttrykk…; hvis.sett-sann…)

hvis.sett-uttrykk: Et logisk uttrykk. hvis.sett-uttrykk kan inneholde hva som helst så lenge uttrykket kan resultere i en boolsk verdi. Hvis uttrykket resulterer i et tall, betraktes 0 som USANN, og alle andre tall betraktes som SANN.

hvis.sett-sann: Verdien som returneres hvis hvis.sett-uttrykket er SANN. hvis.sett-sann kan inneholde en hvilken som helst verdi. Hvis hvis.sett-sann utelates (det finnes et semikolon, men ingen verdi) og hvis.sett-uttrykk vurderes til SANN, vil HVIS.SETT returnere 0.

hvis.sett-uttrykk…: Et valgfritt logisk uttrykk som skal vurderes hvis hvis.sett-uttrykket er USANN. hvis.sett-uttrykk kan inneholde hva som helst så lenge uttrykket kan resultere i en boolsk verdi. Hvis uttrykket resulterer i et tall, betraktes 0 som USANN, og alle andre tall betraktes som SANN.

hvis.sett-sann…: Verdien som returneres hvis hvis.sett-uttrykk… er SANN. hvis.sett-sann kan inneholde en hvilken som helst verdi. Hvis hvis.sett-sann… utelates (det finnes et semikolon, men ingen verdi) og hvis.sett-uttrykk vurderes til SANN, vil HVIS.SETT returnere 0.

Notater

Hvis alle uttrykk er USANN, returneres en feil.
Du kan angi «SANN» for siste hvis.sett-uttrykk… i formelen, etterfulgt av en standardverdi for hvis.sett-sann… for å spesifisere resultatet hvis alle tidligere uttrykk (inkludert hvis.sett-uttrykk og alle forekomster av hvis.sett-uttrykk…) evaluerer til USANN.

Bruk HVIS.SETT til å lage flere sammenligninger
Tabellen nedenfor viser en liste over elevkarakterer.

	A	B	C
1	Elev	Resultat	Vurdering
2	1	4	Fremragende
3	2	2	Rekrutt
4	3	3	Ekspert
5	4		Ufullstendig
6	5	3,2	Ekspert+
7	6	3,2	Nybegynner

Tabellen nedenfor returnerer vurderingen som er knyttet til et resultat i tabellen over, ved å bruke flere argumenter med hvis.sett-uttrykk….

Formelredigeringen viser formelen =HVIS.SETT(B2=4;"Fremragende";B2=3;"Ekspert";B2=2;"Rekrutt";B2=1;"Nybegynner").

Følgende argumenter brukes i denne formelen:

hvis.sett-uttrykk: «B2=4», som kontrollerer om B2 er lik 4.
hvis.sett-sann: «Fremragende», strengen som returneres hvis B2 er lik 4.
hvis.sett-uttrykk…: «B2=3», som kontrollerer om B2 er lik 3.
hvis.sett-sann…: «Ekspert», strengen som returneres hvis B2 er lik 3.
hvis.sett-uttrykk…: «B2=2», som kontrollerer om B2 er lik 2.
hvis.sett-sann…: «Rekrutt», strengen som returneres hvis B2 er lik 2.
hvis.sett-uttrykk…: «B2=1», som kontrollerer om B2 er lik 1.
hvis.sett-sann…: «Nybegynner», strengen som returneres hvis B2 er lik 1.

For å bruke formelen over med de andre cellene i tabellen endrer du B2 i hvert hvis-uttrykk til en annen celle som inneholder et resultat.

Bruk av SANN for hvis.sett-uttrykk…
Noen ganger evalueres ingen av uttrykkene til SANN, men i stedet for å returnere en feil, kan du angi den returnerte strengen i det endelige hvis.sett-uttrykket. I tabellen over har ikke elev 4 et resultat, så den forrige formelen vil returnere en feil for den eleven. Det kan hende at denne eleven ikke var til stede og fortsatt trenger å fullføre oppgaven, så i stedet for å la feilen stå, kan du legge til et annet hvis.sett-uttrykk for å merke manglende resultater som «Ufullstendig»: I dette eksempelet endres cellereferansen for å finne resultatcellen for elev 4, men alle argumentene er like som de over, og ett ekstra hvis.sett-uttrykk er lagt til på slutten: hvis.sett-uttrykk…: SANN, som legges til som det siste uttrykket. hvis.sett-sann…: «Ufullstendig», strengen som returneres hvis ingen av de andre argumentene evalueres til SANN.

Bruk av SANN for hvis.sett-uttrykk…

Noen ganger evalueres ingen av uttrykkene til SANN, men i stedet for å returnere en feil, kan du angi den returnerte strengen i det endelige hvis.sett-uttrykket. I tabellen over har ikke elev 4 et resultat, så den forrige formelen vil returnere en feil for den eleven. Det kan hende at denne eleven ikke var til stede og fortsatt trenger å fullføre oppgaven, så i stedet for å la feilen stå, kan du legge til et annet hvis.sett-uttrykk for å merke manglende resultater som «Ufullstendig»:

Formelredigeringen viser formelen =HVIS.SETT(B5=4;"Fremragende";B5=3;"Ekspert";B5=2;"Rekrutt+";B5=1;"Nybegynner";SANN;"Ufullstendig").

I dette eksempelet endres cellereferansen for å finne resultatcellen for elev 4, men alle argumentene er like som de over, og ett ekstra hvis.sett-uttrykk er lagt til på slutten:

hvis.sett-uttrykk…: SANN, som legges til som det siste uttrykket.
hvis.sett-sann…: «Ufullstendig», strengen som returneres hvis ingen av de andre argumentene evalueres til SANN.

Mer avanserte sammenligninger
I enkelte tilfeller kan du ha mer avanserte uttrykk der du trenger å bruke en blanding av sammenligningsoperatorer. Skalaen over bruker for eksempel heltall, men la oss si at en annen elev (elev 6) fikk resultatet 3,2. Du kan bruke en formel som den under for å gjøre rede for elever med resultater mellom de fire hovedvurderingene (la B6 være 3,2, resultatet til elev 5): I dette eksempelet er det lagt til flere argumenter med hvis.sett-uttrykk… mellom vurderingene Fremragende, Ekspert, Rekrutt og Nybegynner. hvis.sett-uttrykk…: «B6>3», som kontrollerer om B6 er større enn 3. hvis.sett-sann…: «Ekspert+», strengen som returneres hvis B2 er større enn 3. hvis.sett-uttrykk…: «B6>2», som kontrollerer om B6 er større enn 2. hvis.sett-sann…: «Rekrutt+», strengen som returneres hvis B2 er større enn 2. hvis.sett-uttrykk…: «B6>1», som kontrollerer om B6 er større enn 1. hvis.sett-sann…: «Nybegynner+», strengen som returneres hvis B2 er større enn 1. Dette fungerer fordi HVIS.SETT ser etter det første sanne uttrykket. Hvis en elevs resultat ikke er 4, kontrollerer HVIS.SETT om resultatet er større enn 3. Elev 5 ville fått vurderingen Ekspert+. Som et annet eksempel ville en elev med et resultat på 2,5 fått vurderingen Rekrutt+, fordi vedkommendes resultatet ikke er 4, større enn 3 eller 3, men det er større enn 2.

Mer avanserte sammenligninger

I enkelte tilfeller kan du ha mer avanserte uttrykk der du trenger å bruke en blanding av sammenligningsoperatorer. Skalaen over bruker for eksempel heltall, men la oss si at en annen elev (elev 6) fikk resultatet 3,2. Du kan bruke en formel som den under for å gjøre rede for elever med resultater mellom de fire hovedvurderingene (la B6 være 3,2, resultatet til elev 5):

Formelredigeringen viser formelen =HVIS.SETT(B6=4;"Fremragende"; B6>3; "Ekspert+";B6=3;"Ekspert";B6>2;"Rekrutt+";B6=2;"Rekrutt";B6>1;"Nybegynner+";B5=1;"Nybegynner";SANN;"Ufullstendig").

I dette eksempelet er det lagt til flere argumenter med hvis.sett-uttrykk… mellom vurderingene Fremragende, Ekspert, Rekrutt og Nybegynner.

hvis.sett-uttrykk…: «B6>3», som kontrollerer om B6 er større enn 3.
hvis.sett-sann…: «Ekspert+», strengen som returneres hvis B2 er større enn 3.
hvis.sett-uttrykk…: «B6>2», som kontrollerer om B6 er større enn 2.
hvis.sett-sann…: «Rekrutt+», strengen som returneres hvis B2 er større enn 2.
hvis.sett-uttrykk…: «B6>1», som kontrollerer om B6 er større enn 1.
hvis.sett-sann…: «Nybegynner+», strengen som returneres hvis B2 er større enn 1.

Dette fungerer fordi HVIS.SETT ser etter det første sanne uttrykket. Hvis en elevs resultat ikke er 4, kontrollerer HVIS.SETT om resultatet er større enn 3. Elev 5 ville fått vurderingen Ekspert+. Som et annet eksempel ville en elev med et resultat på 2,5 fått vurderingen Rekrutt+, fordi vedkommendes resultatet ikke er 4, større enn 3 eller 3, men det er større enn 2.

Bruk HVIS.SETT med andre funksjoner
HVIS.SETT kan brukes med andre funksjoner. Denne funksjonen bruker for eksempel REST for å bestemme om året i celle A2 (for dette eksempelet, A2=2020) er et skuddår: Du kan finne ut om to verdier ikke er like ved å bruke sammenligningsoperatoren <>.

Bruk HVIS.SETT med andre funksjoner

HVIS.SETT kan brukes med andre funksjoner. Denne funksjonen bruker for eksempel REST for å bestemme om året i celle A2 (for dette eksempelet, A2=2020) er et skuddår:

Formelredigeringen viser formelen =HVIS.SETT(REST($A2;4)≠0 ;USANN;REST($A2;100)≠0;SANN;REST($A2;400)≠0;USANN; SANN; SANN).

Du kan finne ut om to verdier ikke er like ved å bruke sammenligningsoperatoren <>.

Flere eksempler
=HVIS.SETT(A2>91; "A"; A2>82;"B"; A2>73; "C"; A2>64; "D"; SANN;"F") returnerer bokstavkarakteren «A» for et tall større enn 91, og returnerer en «B» for et tall større enn 82 men mindre enn 92, og så videre for alle verdier mindre enn 65, som returnerer en «F». =HVIS.SETT(A2>91;"A";A2>82;"B";A2>73;"C";A2>64;"D";A2<>0;"Forsøkt";SANN;"Ikke bestått") returnerer bokstavkarakteren «A» for tall større enn 91, og returnerer «B» for tall større enn 82 men mindre enn 92, og så videre. Verdier fra 65 ned til 1 returnerer "Forsøkt». Hvis verdien er 0, returnerer formelen «Ikke bestått». La A2 inneholde «En hund» La A1 = TELLTREFF(A2; REGUTTR("\w+")) =HVIS.SETT(A1 = 0; "Ingen ord"; A1 = 1; "Ett ord"; A1 = 2; "To ord"; A1 > 2; "Flere ord") returnerer «To ord».

Flere eksempler

=HVIS.SETT(A2>91; "A"; A2>82;"B"; A2>73; "C"; A2>64; "D"; SANN;"F") returnerer bokstavkarakteren «A» for et tall større enn 91, og returnerer en «B» for et tall større enn 82 men mindre enn 92, og så videre for alle verdier mindre enn 65, som returnerer en «F».

=HVIS.SETT(A2>91;"A";A2>82;"B";A2>73;"C";A2>64;"D";A2<>0;"Forsøkt";SANN;"Ikke bestått") returnerer bokstavkarakteren «A» for tall større enn 91, og returnerer «B» for tall større enn 82 men mindre enn 92, og så videre. Verdier fra 65 ned til 1 returnerer "Forsøkt». Hvis verdien er 0, returnerer formelen «Ikke bestått».

La A2 inneholde «En hund»

La A1 = TELLTREFF(A2; REGUTTR("\w+"))

=HVIS.SETT(A1 = 0; "Ingen ord"; A1 = 1; "Ett ord"; A1 = 2; "To ord"; A1 > 2; "Flere ord") returnerer «To ord».

Se ogsåOG HVIS IKKE ELLER

Nyttig?

Hjelp for formler og funksjoner

HVIS.SETT

Notater