AVERAGEIF
Funkcija AVERAGEIF vraća prosjek (aritmetičku sredinu) ćelija u skupini koje zadovoljavaju zadani uvjet.
AVERAGEIF(test-vrijednosti; uvjet; prosj-vrijednosti)
test-vrijednosti: Zbirka koja sadrži vrijednosti za testiranje. test-vrijednosti mogu sadržavati bilo koju vrijednost
uvjet: Izraz koji uspoređuje ili testira vrijednosti i rezultira booleovom vrijednosti TRUE ili FALSE. uvjet može uključivati operatore za usporedbu, konstante, operatora za ulančavanje, reference i zamjenske znakove. Možete koristiti zamjenske znakove koji će označavati bilo koji znak ili više znakova u izrazu. Možete upotrijebiti ? (upitnik) za predstavljanje jednog znaka, * (zvjezdicu) za predstavljanje više znakova i ~ (tildu) kako biste odredili da sljedeći znak treba biti usklađen umjesto da bude korišten kao zamjenski znak. uvjet može sadržavati i funkciju REGEX umjesto zamjenskih znakova.
prosj-vrijednosti: Opcionalna kolekcija vrijednosti čiji se prosjek računa. prosj-vrijednosti je referenca na jednu zbirku ćelija, koja može sadržavati samo brojčane vrijednosti ili Booleove vrijednosti.
Napomene
Svaka vrijednost se uspoređuje s uvjetom. Ako vrijednost zadovoljava uvjetni test, odgovarajuća vrijednost u prosj-vrijednostima se uključuje u prosjek.
prosj-vrijednosti i test-vrijednosti (ako su određene) moraju biti iste veličine.
Ako se prosj-vrijednosti izostave, test-vrijednosti se koriste za prosj-vrijednosti.
Ako se izostave prosj-vrijednosti ili su iste kao test-vrijednosti, test-vrijednosti mogu sadržavati samo brojčane vrijednosti ili Booleove vrijednosti.
Ako se zahtijeva više od jednog uvjeta ili skupa test-vrijednosti, razmislite o upotrebi funkcije AVERAGEIFS.
Primjeri |
|---|
U sljedećoj tablici: |
A | B | C | D | |
|---|---|---|---|---|
1 | Dob | Spol | Status | Dohodak |
2 | 35 | M | M | 71 000 |
3 | 27 | F | M | 81 000 |
4 | 42 | M | M | 86 000 |
5 | 51 | M | S | 66 000 |
6 | 28 | M | S | 52 000 |
7 | 49 | F | S | 62 000 |
8 | 63 | F | M | 89 000 |
9 | 22 | M | M | 34 000 |
10 | 29 | F | S | 42 000 |
11 | 35 | F | M | 56 000 |
12 | 33 | M | S | 62 000 |
13 | 61 | M | M | 91 000 |
=AVERAGEIF(A2:A13; "<40"; D2:D13) vraća približno 56 857, prosječni dohodak ljudi u dobi ispod 40 godina. =AVERAGEIF(B2:B13; "=F"; D2:D13) vraća 66 000, prosječni dohodak žena (označeno s "F" u stupcu B). =AVERAGEIF(C2:C13; "S"; D2:D13) vraća 56 800, prosječni dohodak samaca (označeno sa "S" u stupcu C). =AVERAGEIF(A2:A13; ">=40"; D2:D13) vraća 78 800, prosječni dohodak ljudi od 40 godina ili starijih. Također možete koristiti operator ≥. =AVERAGEIF(A2:A13; "<> M"; D2:D13) vraća 56 800, prosječni dohodak ljudi koji nisu oženjeni/udani. Također možete koristiti operator ≠ |
Primjer u kojem se upotrebljava REGEX |
|---|
U sljedećoj tablici: |
A | B | |
|---|---|---|
1 | 45 | marina@primjer.com |
2 | 41 | Aaron |
3 | 29 | ivan@primjer.com |
4 | 64 | katarina@primjer.com |
5 | 12 | Sarah |
=AVERAGEIF(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"); A1:A5) vraća 46, prosjek svih ćelija u A1:A5 gdje odgovarajuća ćelija u B1:B2 sadrži e-mail adresu. |