SUMIF

SUMIF 函數會傳回數字集合的加總，僅包含滿足指定條件的數字。

SUMIF(測試值, 條件, 加總值)

測試值： 包含要測試的數值的集合。 測試值可以包含任何值。

條件： 用來比較或測試布林值 TRUE 或 FALSE 中數值和結果的表示式。條件可包含比較運算子、常數、連集串連運算子、參照和萬用字元。您可以使用萬用字元來匹配表示式中的任何單一或多個字元。您可以使用 ? （問號）來表示一個字元、使用 *（星號）來表示多個字元，以及使用 ~（波浪號）來指定之後的字元需要進行匹配（而不是當作萬用字元）。條件也可包含 REGEX 函數而非萬用字元。

加總值： 包含求加總的數值的集合（可留空）。 加總值可以包含數值、日期/時間值或持續時間值。它應該與測試值具有相同的範圍。

附註

如果省略加總值，則預設值為測試值。
雖然測試值可以包含任何值，但是其通常應該包含相同數值類型的值。
如果省略加總值，則測試值一般僅包含數字或持續時間值。

範例
提供下列表格：

	A	B	C	D	E
1	1	10	a	a	c
2	2	20	b	c	b
3	3	30	a	a	c
4	4	40
5	5	50	1	5	9

=SUMIF(A1:A5, "<5") 會傳回 10，因為 1、2、3 和 4（測試值範圍 A1:A5 中所含的小於 5 的值（條件）的加總是 10。

=SUMIF(A1:A5, "<5", B1:B5) 會傳回 100，因為 10、20、30 和 40（針對直欄 A 中小於 5 的那些值，直欄 B（加總值是 B1:B5）中的對應值）的加總是 100。

=SUMIF(D1:E3, "=c", A3:B5) 會傳回 84，因為對應於測試值中那些輸入格（等於「c」（輸入格 E1、D2 和 E3））的加總值（輸入格 B3、A4 和 B5）中的那些輸入格包含 30、4 和 50，其加總為 84。

=SUMIF(A1:D5, 1) 或 =SUMIF(A1:D5, SUM(1)) 皆會傳回 2，此為範圍內所有 1 的加總。

使用 REGEX 的範例
提供下列表格：

	A	B
1	45	john@appleseed.com
2	41	Aaron
3	29	janedoe@appleseed.com
4	64	jake@appleseed.com
5	12	Sarah

=SUMIF(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"),A1:A5) 會傳回 138，即 A1:A5 中所有輸入格的加總，而 B1:B5 中的對應輸入格包含電子郵件地址。

也請參閱AVERAGEIF AVERAGEIFS SUMIFS

有幫助？

公式與函數輔助說明

SUMIF

附註