SUMIFS

SUMIFS 函數會傳回測試值符合指定條件之集合中輸入格的加總。

SUMIFS(加總值, 測試值, 條件, 測試值⋯, 條件⋯)

加總值： 包含要加總的值集合。 加總值可以是數字值、日期/時間值或持續時間值。

測試值： 包含要測試的值集合。 測試值可以包含任何值。

條件： 用來比較或測試布林值 TRUE 或 FALSE 中的值和結果之表示式。條件可包含比較運算子、常數、連集串連運算子、參照和萬用字元。你可以使用萬用字元來匹配表示式中的任何單一或多個字元。你可以使用 ? （問號）來表示一個字元、使用 *（星號）來表示多個字元，以及使用 ~（波浪號）來指定之後的字元需要進行匹配（而不是當作萬用字元）。條件亦可包含 REGEX 函數（而非萬用字元）。

測試值⋯： 選擇性地併入包含要測試之值的一個或多個其他集合。每個測試值集合後都必須緊跟條件表示式。此測試值, 條件模式可以視需要進行重複。

條件⋯： 如果加入了測試值的選用集合，條件⋯就是會產生布林值 TRUE 或 FALSE 的其他表示式。在每個測試值集合後必須有一個條件；因此，此函數一律具有奇數數目的引數。

備註

對於每個測試和條件值對，對應的（集合內的相同位置）輸入格或值會與該條件進行比較。如果所有條件都符合，則加總值中對應的輸入格或值會併入在該加總中。
所有集合的大小必須相同。

範例
提供下列表格：

	A	B	C
1	噸	等級	日期
2	6	1	10/12/2012
3	15	2	10/12/2012
4	5	1	13/12/2012
5	7	2	13/12/2012
6	8	2	14/12/2012
7	6	1	15/12/2012
8	7	2	15/12/2012
9	4	2	16/12/2012
10	7	1	16/12/2012
11	8	2	16/12/2012
12	5	1	17/12/2012
13	11	2	20/12/2012

=SUMIFS(A2:A13, B2:B13, "=1", C2:C13, ">=13/12/2012", C2:C13, "<=17/12/2012") 會傳回 23，12 月 17 日那週交貨的商品噸數為等級「1」。集合 A2:A13 包含噸數，即要加總的值（加總值）。集合 B2:B13（測試值）包含第一個要測試等級「1」（條件）的值。集合 C2:C13（測試值）包含第二個要測試以尋找開始日期（條件...）符合項目的值。此相同的範圍也包含要測試的第三個值，其為結束日期。橫列 4（5 噸）、7（6 噸）、10（7 噸）和 12（5 噸）滿足所有條件，而這些項目的加總為 23 噸。你也可以使用 ≥ 和 ≤ 運算子。

=SUMIFS(A2:A13, B2:B13, "=2", C2:C13, ">=13/12/2012", C2:C13, "<=17/12/2012") 會傳回 34，同一週期間交貨的商品噸數為等級 2。你也可以使用 ≥ 和 ≤ 運算子。

=SUMIFS(A2:A13, B2:B13, "<>2", C2:C13, ">=10/12/2012", C2:C13, "<=20/12/2012") 會傳回 29，任何週期間交貨且不屬於等級 2 的商品噸數。你也可以使用 ≠、≥ 和 ≤ 運算子。

使用 REGEX 的範例
提供下列表格：

	A	B
1	45	marina@example.com
2	41	Aaron
3	29	michael@example.com
4	64	jake@example.com
5	12	Sarah

=SUMIFS(A1:A5, B1:B5,REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})",), A1:A5, ">10") 會傳回 138，這是 A1:A5 中大於 10 的輸入格之加總，且 B1:B5 中的對應的輸入格包含電郵地址。

也請參閲AVERAGEIF AVERAGEIFS SUMIF SUM

有幫助？

公式與函數輔助説明

SUMIFS

備註