COUNTIFS

COUNTIFS 函数返回一个或多个集合内满足给定条件（每个集合一个条件）的单元格的个数。

COUNTIFS(待检验的值, 条件, 待检验的值…, 条件…)

待检验的值： 集合，包含要测试的值。 待检验的值可以包含任何值。

条件： 比较或检验值，并返回布尔值 TRUE 或 FALSE 的表达式。条件可包括比较运算符、常数、与符号并置运算符、引用表达式和通配符。您可以使用通配符来匹配表达式中的任何单个字符或多个字符。您可以使用 ? （问号）表示一个字符，*（星号）表示多个字符，并使用 ~（波浪号）来指定下一个字符应当匹配，而非用作通配符。条件还可包含 REGEX 函数，而无需通配符。

待检验的值…： 可含有一个或多个附加集合（含有要测试的值）。每个待检验的值集合后必须紧跟一个条件表达式。此模式的待检验的值、条件可根据需要尽可能多地重复。

条件…： 如果待检验的值的可选集合包括在内，条件… 表示结果为布尔值 TRUE 或 FALSE 的附加表达式。每个待检验的值集合后必须有一个条件表达式；因此，此函数始终拥有偶数个参数。

注释

待检验的值中的每个值都与相应的条件进行比较。如果每个集合中的相应值满足相应的条件测试，则计数增加 1。

示例
假设表格如下：

	A	B	C	D
1	年龄	性别	婚姻状况	工资
2	35	男	已婚	71000
3	27	女	已婚	81000
4	42	男	已婚	86000
5	51	男	未婚	66000
6	28	男	未婚	52000
7	49	女	未婚	62000
8	63	女	已婚	89000
9	22	男	已婚	34000
10	29	女	未婚	42000
11	35	女	已婚	56000
12	33	男	未婚	62000
13	61	男	已婚	91000

=COUNTIFS(A2:A13, "<40", B2:B13, "=男") 返回 4（四十岁以下的男性人数，在 B 列中以“男”表示）。

=COUNTIFS(A2:A13, "<>35", B2:B13, "=男") 返回 6，即非 35 岁的男性（在 B 列中以“男”表示）人数。

=COUNTIFS(A2:A13, "<40", B2:B13, "=男", C2:C13, "=未婚") 返回 2（四十岁以下的单身男性人数，在 C 列中以“未婚”表示）。

=COUNTIFS(A2:A13, "<40", B2:B13, "=男", C2:C13, "=已婚") 返回 2（四十岁以下的已婚男性人数，在 C 列中以“已婚”表示）。

=COUNTIFS(A2:A13, "<40", B2:B13, "=女") 返回 3（四十岁以下的女性人数，在 B 列中以“女”表示）。

使用 REGEX 示例
假设表格如下：

	A	B
1	45	marina@example.com
2	41	Aaron
3	29	michael@example.com
4	64	katrina@example.com
5	12	Sarah

=COUNTIFS(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"), A1:A5, ">10") 返回 A1:A5 中大于 10 且对应单元格在 B1:B5 中包含电子邮件地址的单元格的数字。

另请参阅COUNT COUNTIF COUNTA COUNTBLANK

有帮助?

公式与函数帮助

COUNTIFS

注释