ANTAL.OMF

Funktionen ANTAL.OMF returnerar antalet celler i en eller flera samlingar som uppfyller ett angivet villkor (ett villkor per samling).

ANTAL.OMF(test-värden; villkor; test-värden…; villkor…)

test-värden: En samling värden som ska testas. test-värden kan innehålla valfritt värde.

villkor: Ett uttryck som jämför eller testar värden och resultat i det booleska värdet SANT eller FALSKT. villkor kan innehålla jämförelseoperatorer, konstanter, sammanfogningsoperatorn & (ampersand), referenser samt jokertecken. Du kan använda jokertecken till att matcha ett enskilt eller flera tecken i uttrycket. Du kan använda ett ? (frågetecken) istället för ett tecken, en * (asterisk) istället för flera tecken och en ~ (tilde) för att ange att det efterföljande tecknet ska matchas snarare än användas som ett jokertecken. villkor kan även innehålla en REGEX-funktion istället för jokertecken.

test-värden…: Du kan lägga till en eller flera ytterligare samlingar som innehåller värden som ska testas. Varje test-värden-samling måste omedelbart följas av ett villkor-uttryck. Mönstret test-värden, villkor kan upprepas så många gånger som det behövs.

villkor…: Om en valfri samling test-värden är inkluderad blir villkor… ytterligare ett uttryck som resulterar i det booleska värdet SANT eller FALSKT. Ett villkorsuttryck måste följa varje test-värden-samling och därför har den här funktionen alltid ett jämnt antal argument.

Anmärkningar

Varje värde i test-värden jämförs med motsvarande villkor. Om de motsvarande värdena i varje samling uppfyller motsvarande villkor ökas antalet med 1.

Exempel
Med följande tabell som exempel:

	A	B	C	D
1	Ålder	Kön	Status	Lön
2	35	M	M	71 000
3	27	F	M	81 000
4	42	M	M	86 000
5	51	M	S	66 000
6	28	M	S	52 000
7	49	F	S	62 000
8	63	F	M	89 000
9	22	M	M	34 000
10	29	F	S	42 000
11	35	F	M	56 000
12	33	M	S	62 000
13	61	M	M	91 000

=ANTAL.OMF(A2:A13; "<40"; B2:B13; "=M") returnerar 4, antalet män (indikeras med "M" i kolumn B) under 40.

=ANTAL.OMF(A2:A13; "<>35"; B2:B13; "=M") returnerar 6 som är antalet män (indikeras med "M" i kolumn B) som inte är 35 år gamla. Du kan också använda operatorn ≠.

=ANTAL.OMF(A2:A13; "<40"; B2:B13; "=M"; C2:C13; "=S") returnerar 2, antalet män som är ensamstående (indikeras av "S" i kolumn C) och under 40.

=ANTAL.OMF(A2:A13; "<40"; B2:B13; "=M"; C2:C13; "=M") returnerar 2, antalet män som är gifta (indikeras av "M" i kolumn C) och under 40.

=ANTAL.OMF(A2:A13; "<40"; B2:B13; "=F") returnerar 3, antalet kvinnor (indikeras med "F" i kolumn B) under 40.

Exempel med REGEX
Med följande tabell som exempel:

	A	B
1	45	marina@example.com
2	41	Axel
3	29	michael@example.com
4	64	katrina@example.com
5	12	Sara

=ANTAL.OMF(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"); A1:A5; ">10") returnerar antalet celler i A1:A5 som är större än 10 och där motsvarande cell i B1:B5 innehåller en e-postadress.

Se ävenANTAL ANTAL.OM ANTALV ANTAL.TOMMA

Var detta till hjälp?

Formler och funktioner Hjälp

ANTAL.OMF

Anmärkningar