REGEX.EXTRACT

Funkcia REGEX.EXTRACT vráti zhody alebo zaznamenané skupiny v zhode daného regulárneho výrazu v zdrojovom reťazci.

REGEX.EXTRACT(zdrojový reťazec; reťazec regulárneho výrazu; výskyt zhody; výskyt zaznamenávaných skupín)

zdrojový reťazec: Hodnota reťazca, ktorá sa má spárovať.

reťazec bežného výrazu: Hodnota reťazca predstavujúceho regulárny výraz použitý na porovnanie so zdrojovým reťazcom.

výskyt zhody: Voliteľné celé číslo označujúce, ktorá zhoda sa má vrátiť v prípade viacerých zhôd. Akceptované sú aj záporné celé čísla a umožňujú spätný prístup k zhodám, takže -1 je posledná zhoda a tak ďalej. Ak sa zadá 0, vráti sa súbor všetkých zhôd. Ak sa vynechá, vráti sa prvá zhoda.

výskyt zaznamenávaných skupín: Voliteľné celé číslo označujúce, ktorá zaznamenaná skupina v rámci zhody má byť vrátená v prípade, že v regulárnom výraze sú zaznamenané skupiny. Záporné hodnoty nie sú akceptované. Ak sa 0, vráti sa súbor všetkých zaznamenaných skupín. Ak sa vynechá, vráti sa celá zhoda.

Poznámky

Reťazec regulárneho výrazu musí spĺňať normu ICU.

Príklady
Ak máte dáta, ktoré sa jednoducho nezmestia do riadkov a stĺpcov hárka, na ich zjednodušenie môžete použiť REGEX.EXTRACT. Napríklad v tabuľke nižšie majú dáta istú štruktúru, ale môže byť náročné dáta manuálne oddeliť do viacerých buniek na kontrolu.

	A
1	Užívateľské hodnotenia
2	Email: jtalma@icloud.com Meno: Julie Talma Dátum: 17/05/2021
3	Email: danny_rico@icloud.com Meno: Danny Rico Dátum: 02/06/2021

Na vyriešenie tohto problému môžete do tabuľky pridať ďalšie stĺpce pre hodnoty ako sú Meno, Email, Hodnotenie a Dátum, a potom pomocou funkcie REGEX.EXTRACT nájsť dáta, ktoré potrebujete, a vrátiť ich v bunke.

Napríklad na vrátenie mena môžete zadať tento vzorec:

Editor vzorcov zobrazujúci vzorec =REGEX.EXTRACT(A2,"(?<=Meno: )(.*)(?= Dátum)".

V tomto vzorci sa používajú tieto argumenty:

zdrojový reťazec: A2, teda bunka, ktorá obsahuje dáta, ktoré chcete použiť pri hľadaní mena.
reťazec bežného výrazu: "(?<=Meno: )(.*)(?= Dátum)", teda bežný výraz, ktorý vyhľadáva text medzi reťazcom "Meno: " a " Dátum".

Tento vzorec je možné zopakovať pre každý riadok dát, aby sa vrátilo meno každej osoby, ktorá odpovedala v prieskume, tak, že zmeníte zdrojový reťazec, aby existovala zhoda s inými bunkami, ktoré obsahujú informácie o užívateľských hodnoteniach.

Napríklad môžete zadať tento vzorec:

Editor vzorcov zobrazujúci vzorec =REGEX.EXTRACT(A2,"[A-Z0-9a-z._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,4}")

V tomto vzorci sa používajú tieto argumenty:

zdrojový reťazec: A2, teda bunka, ktorá obsahuje dáta, ktoré chcete použiť pri hľadaní emailu.
reťazec bežného výrazu: "[A-Z0-9a-z._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,4}", teda bežný výraz, ktorý vyhľadáva istý vzor medzi emailovými adresami.

Reorganizácia dát zo zoznamu pomocou argumentu výskyt zhody
Niekedy môžete mať k dispozícii dáta ako v tabuľke nižšie (nazvanej Dodávatelia), ktorá zoskupuje hodnoty v bunke:

Dodávateľ	Položka
A	Šošovica, Fazuľa Garbanzo, Fazuľa Lima
B	Jablká, Pomaranče, Citróny
C	Quinoa, Ryža, Chia

Ak chcete oddeliť hodnoty podľa obchodu a postavenia, najprv môžete vytvoriť novú tabuľku ako napríklad tabuľka nižšie:

	A	B	C	D
1	Postavenie	A	B	C
2	1
3	2
4	3

Ak chcete, aby sa vrátila hodnota Šošovica, položka s najvyšším postavením pre Dodávateľa A, môžete použiť tento vzorec v bunke B2 novej tabuľky. Vráti sa Šošovica, položka s najvyšším postavením pre Dodávateľa A:

Editor vzorcov zobrazujúci vzorec =REGEX.EXTRACT(Dodávatelia::B2,"\w+",ROW(A2)-1).

V tomto vzorci sa používajú tieto argumenty:

zdrojový reťazec: Dodávatelia::B2, teda bunka, ktorá obsahuje dáta, ktoré chcete použiť pri hľadaní. V tomto prípade chcete zoznam prehľadávať v tejto bunke.
reťazec bežného výrazu: "\w+", teda bežný výraz, ktorý vyhľadá slovo.
výskyt zhody: ROW(A2)-1. V tomto prípade existujú 3 zhody pre každú funkciu REGEX.EXTRACT a na nastavenie konkrétnej zhody, ktorú potrebujete, môžete použiť ROW. ROW(A2) vráti číslo riadka vybranej bunky (2) a pridá sa -1, aby sa z výsledku odpočítala hlavička riadka. Inak by sa v tomto príklade vrátila hodnota Fazuľa Garbanzo (druhá zhoda).
Ak vynecháte výskyt zhody, výsledok pre každého dodávateľa je vždy prvé vrátené slovo (Šošovica pre Dodávateľa A, Jablká pre Dodávateľa B a tak ďalej).

Vzorec vyššie je možné ľahko upravovať a dokončiť tak tabuľku pre ďalších dodávateľov a položky.

Ak chcete pre jednotlivého dodávateľa vrátiť ďalšie populárne produkty, môžete upraviť výskyt zhody. Ak sa má napríklad vrátiť Fazuľa Garbanzo, ďalšia najpopulárnejšia položka pre Dodávateľa A, môžete zmeniť odkaz na bunku v argumente výskyt zhody z A2 na A3.
Ak chcete vrátiť hodnoty pre iného dodávateľa, môžete upraviť zdrojový reťazec. Ak sa má napríklad vrátiť Jablká, najpopulárnejšia položka pre Dodávateľa B, môžete zmeniť odkaz na bunku v argumente zdrojový reťazec z B2 na B3.

Ďalšie príklady
A1 môže byť „marina@example.com john@example.ca mike@example.de“. =REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})") vráti „marina@example.com“. =REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2) vráti „john@example.ca“. =REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; -1) vráti „mikeexample.de“. =REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 1; 1) vráti „marina“. =REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2; 2) vráti „example.ca“.

Ďalšie príklady

A1 môže byť „marina@example.com john@example.ca mike@example.de“.

=REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})") vráti „marina@example.com“.

=REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2) vráti „john@example.ca“.

=REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; -1) vráti „mikeexample.de“.

=REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 1; 1) vráti „marina“.

=REGEX.EXTRACT(A1; "([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"; 2; 2) vráti „example.ca“.

Pozrite tiežREGEX

Boli tieto informácie užitočné?

Pomocník pre Vzorce a funkcie

REGEX.EXTRACT

Poznámky