AANTALLEN.ALS
De functie AANTALLEN.ALS retourneert het aantal cellen in een of meer verzamelingen dat aan de opgegeven voorwaarden voldoet (één voorwaarde per verzameling).
AANTALLEN.ALS(toetswaarden; voorwaarde; toetswaarden…; voorwaarde…)
toetswaarden: Een verzameling met waarden die moeten worden getoetst. toetswaarden kan uit een willekeurige waarde bestaan.
voorwaarde: Een uitdrukking die waarden vergelijkt of test en die resulteert in de booleaanse waarde WAAR of ONWAAR. voorwaarde kan vergelijkingsoperatoren, constanten, de samenvoegingsoperator "&", verwijzingen en jokers bevatten. Je kunt jokers gebruiken om een of meer tekens in de uitdrukking te zoeken. Je kunt een ? (vraagteken) gebruiken om één teken te representeren, een * (asterisk) om meerdere tekens te representeren en het teken ~ (tilde) om aan te geven dat het daaropvolgende teken moet worden gezocht en niet als joker moet worden beschouwd. voorwaarde kan ook een REGEX-functie in plaats van jokers bevatten.
toetswaarden…: Optioneel kunnen een of meer extra verzamelingen met te toetsen waarden worden toegevoegd. Elke verzameling toetswaarden moet direct worden gevolgd door een uitdrukking met een voorwaarde. Dit patroon van toetswaarden; voorwaarde kan zo vaak worden herhaald als nodig is.
voorwaarde…: voorwaarde… is een extra uitdrukking die volgt op een optionele verzameling toetswaarden en resulteert in de booleaanse waarde WAAR of ONWAAR. Omdat elke verzameling toetswaarden moet worden gevolgd door één uitdrukking met een voorwaarde, heeft deze functie altijd een even aantal argumenten.
Opmerkingen
Elke waarde in toetswaarden wordt vergeleken met de corresponderende voorwaarde. Als de waarden in elke verzameling aan de corresponderende voorwaarden voldoen, wordt het aantal verhoogd met 1.
Voorbeelden |
|---|
Gegeven wordt de onderstaande tabel: |
A | B | C | D | |
|---|---|---|---|---|
1 | Leeftijd | Gesl. | Gehuwd | Salaris |
2 | 35 | M | J | 71000 |
3 | 27 | V | J | 81000 |
4 | 42 | M | J | 86000 |
5 | 51 | M | N | 66000 |
6 | 28 | M | N | 52000 |
7 | 49 | V | N | 62000 |
8 | 63 | V | J | 89000 |
9 | 22 | M | J | 34000 |
10 | 29 | V | N | 42000 |
11 | 35 | V | J | 56000 |
12 | 33 | M | N | 62000 |
13 | 61 | M | J | 91000 |
=AANTALLEN.ALS(A2:A13; "<40"; B2:B13; "=M") retourneert 4, het aantal mannen (aangegeven met "M" in kolom B) dat jonger dan veertig jaar is. =AANTALLEN.ALS(A2:A13; "<40"; B2:B13; "=M"; C2:C13; "=N") retourneert 2, het aantal ongehuwde mannen (aangegeven met "N" in kolom C) dat jonger dan veertig jaar is. =AANTALLEN.ALS(A2:A13; "<40";B2:B13; "=M"; C2:C13; "=J") retourneert 2, het aantal gehuwde mannen (aangegeven met "J" in kolom C) dat jonger dan veertig jaar is. =AANTALLEN.ALS(A2:A13; "<40"; B2:B13; "=V") retourneert 3, het aantal vrouwen (aangegeven met "V" in kolom B) dat jonger dan veertig jaar is. |
Voorbeeld met REGEX |
|---|
Gegeven wordt de onderstaande tabel: |
A | B | |
|---|---|---|
1 | 45 | john@appleseed.com |
2 | 41 | Aaron |
3 | 29 | janedoe@appleseed.com |
4 | 64 | jake@appleseed.com |
5 | 12 | Sarah |
=AANTALLEN.ALS(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"); A1:A5; ">10") retourneert het aantal cellen in A1:A5 dat groter is dan 10 en waarbij de overeenkomende cel in B1:B5 een e-mailadres bevat. |