LASKE.JOS
LASKE.JOS-funktio palauttaa joukon niiden solujen määrän, jotka täyttävät annetun ehdon.
LASKE.JOS(testimatriisi; ehto)
testimatriisi: Testattavat arvot sisältävä joukko. testimatriisi voi sisältää mitä tahansa arvoja.
ehto: Lauseke, joka vertaa tai testaa arvoja ja jonka tulos on totuusarvo TOSI tai EPÄTOSI. ehto voi sisältää vertailuoperaattoreita, vakioita, yhdistysoperaattorin, viittauksia ja yleismerkkejä. Yleismerkeillä voit merkitä yhden tai useampia merkkejä lausekkeessa. Kysymysmerkki (?) tarkoittaa yhtä merkkiä, tähti (*) tarkoittaa useita merkkejä ja aaltoviiva (~) tarkoittaa, että seuraava merkki ei ole yleismerkki, vaan sen pitää täsmätä. ehto voi myös sisältää yleismerkkien sijasta SÄÄNNÖLLINEN.LAUSEKE-funktion.
Huomautuksia
Jokaista testimatriisi-arvoa verrataan ehtoon. Jos arvo täyttää ehdollisen testin, se lasketaan mukaan.
Esimerkkejä |
|---|
Seuraavan taulukon tiedot eivät ole merkityksellisiä, mutta niitä käytetään havainnollistamaan, minkä tyyppisiä argumentteja LASKE.JOS sisällyttää tulokseensa. Seuraavassa taulukossa: |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | TOSI | TOSI | EPÄTOSI | EPÄTOSI |
5 | 200 | 400 |
=LASKE.JOS(A1:D1; ">0") palauttaa 4, koska kaikkien joukon solujen arvo on suurempi kuin 0. =LASKE.JOS(A1:D1; "<>100") palauttaa 3, koska joukon kolmella solulla on arvo, joka ei ole 100. Voit myös käyttää operaattoria ≠. =LASKE.JOS(A3:D3; ">=100") palauttaa 3, koska kaikki kolme numeroa ovat suurempia tai yhtä suuria kuin 100 ja tekstiarvo jätetään huomioimatta vertailussa. Voit myös käyttää operaattoria ≥. =LASKE.JOS(A1:D5; "=ipsum") palauttaa 1, koska merkkijono "ipsum" esiintyy alueen viittaamassa joukossa kerran. =LASKE.JOS(A1:D5; "=*t") palauttaa 2, koska t-kirjaimeen päättyvä merkkijono esiintyy alueen viittaamassa joukossa kaksi kertaa. |
SÄÄNNÖLLINEN.LAUSEKE-funktiota käyttävä esimerkki |
|---|
Seuraavassa taulukossa: |
A | B | |
|---|---|---|
1 | 45 | marina@example.com |
2 | 41 | Aaron |
3 | 29 | michael@example.com |
4 | 64 | katrina@example.com |
5 | 12 | Sarah |
=LASKE.JOS(B1:B5; SÄÄNNÖLLINEN.LAUSEKE("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) palauttaa alueen B1:B5 sellaisten solujen lukumäärän, jotka sisältävät sähköpostiosoitteen. |
Esimerkki – Kyselytulokset |
|---|
Tämä esimerkki yhdistää tilastofunktioissa käytetyt esimerkit. Se perustuu kuvitteelliseen kyselyyn. Kysely oli lyhyt (vain viisi kysymystä) ja siinä oli rajallinen määrä vastaajia (10). Jokaiseen kysymykseen voitiin vastata asteikolla 1–5 (esimerkiksi väliltä "ei koskaan" –"aina") tai olla vastaamatta. Jokaiselle kyselylle annettiin numero (ID#) ennen lähettämistä. Tulokset näkyvät seuraavassa taulukossa. Vastaukset, jotka olivat alueen ulkopuolella (virheellisiä) tai joihin ei vastattu, on osoitettu taulukossa tyhjillä soluilla. |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Joidenkin funktioiden havainnollistamiseksi oletetaan, että kyselyn numero sisälsi kirjainetuliitteen ja että asteikko oli A–E eikä 15. Taulukko näyttäisi silloin tältä: |
A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Tätä datataulukkoa ja tiettyjä tilastofunktioita käyttäen saat tietoa kyselyn tuloksista. Pidä mielessä, että esimerkki on tarkoituksella pieni, joten tulokset saattavat näyttää ilmiselviltä. Jos sinulla olisi 50, 100 tai enemmän vastaajia ja paljon enemmän kysymyksiä, tulokset eivät olisi ilmiselviä. |
Funktio ja argumentit | Tuloksen kuvaus |
|---|---|
=KORRELAATIO(B2:B11;C2:C11) | Määrittää kysymysten 1 ja 2 korrelaation käyttäen lineaarista regressioanalyysiä. Korrelaatio on sen mitta, kuinka paljon kaksi muuttujaa (tässä tapauksessa kyselyn kysymysten vastaukset) muuttuvat yhdessä. Tämä tarkastelisi kysymystä: Jos vastaaja vastasi kysymykseen 1 korkeammalla (tai matalammalla) arvolla kuin kysymyksen 1 keskiarvo, vastasiko vastaaja myös kysymykseen 2 korkeammalla (tai matalammalla) arvolla kuin kysymyksen 2 keskiarvo? Tässä tapauksessa vastaukset eivät korreloi erityisen hyvin (-0,1732) |
=LASKE(A2:A11) tai =LASKE.A(A2:A11) | Määrittää palautettujen kyselyiden kokonaismäärän (10). Huomaa, että jos kyselynumero ei olisi numeerinen, sinun pitäisi käyttää LASKE.A-funktiota LASKE-funktion sijasta. |
=LASKE(B2:B11) tai =LASKE.A(B2:B11) | Määrittää ensimmäisen kysymyksen vastausten määrän (9). Laajentamalla tämän kaavan koko riviin voit määrittää kaikkien kysymysten vastausten määrään. Koska kaikki data on numeerista, LASKE.A palauttaa samat vastaukset. Jos kyselyssä olisi käytetty vastauksia 1–5:n sijasta A–E, sinun pitäisi käyttää LASKE.A-funktiota tulosten laskemiseen. |
=LASKE.TYHJÄT(B2:B11) | Määrittää virheellisiä tai puuttuvia vastauksia kuvaavien tyhjien solujen määrän. Jos laajennat tämän kaavan koko rivin ylitse, näet, että kysymyksessä 3 (sarake D) on kolme virheellistä tai puuttuvaa vastausta. Tämä saattaa antaa aihetta tarkistaa, oliko kyselyn tämä kysymys kiistanalainen tai huonosti muotoiltu, koska missään muussa kysymyksessä ei ollut enempää kuin yksi virheellinen tai puuttuva vastaus. |
=LASKE.JOS(B2:B11;"=5") | Määrittää niiden vastaajien määrän, jotka vastasivat "5" tiettyyn kysymykseen (tässä tapauksessa kysymys 1). Jos laajennat tämän kaavan koko rivin ylitse, huomaat, että vain kysymyksissä 1 ja 4 oli vastaajia, jotka vastasivat kysymykseen "5". Jos kyselyssä olisi käytetty vastauksia A–E, sinun pitäisi kirjoittaa =LASKE.JOS(B2:B11;"=E"). |
=LASKE.JOS(B2:B11;"<>5") | Määrittää niiden vastaajien määrän, jotka eivät vastanneet 5 tiettyyn kysymykseen (tässä tapauksessa kysymys 1). |
=KOVARIANSSI(B2:B11;C2:C11) | Määrittää kysymysten 1 ja 2 kovarianssin. Kovarianssi on sen mitta, kuinka paljon kaksi muuttujaa (tässä tapauksessa kyselyn kysymysten vastaukset) muuttuvat yhdessä. Tämä tarkastelisi kysymystä: Jos vastaaja vastasi kysymykseen 1 korkeammalla (tai matalammalla) arvolla kuin kysymyksen 1 keskiarvo, vastasiko vastaaja myös kysymykseen 2 korkeammalla (tai matalammalla) arvolla kuin kysymyksen 2 keskiarvo? Huomaa: KOVARIANSSI ei toimisi taulukon kanssa, joka käyttää asteikkoa A–E, koska se vaatii numeerisia argumentteja. |
=KESKIHAJONTA(B2:B11) tai =KESKIHAJONTAP(B2:B11) | Määrittää kysymyksen 1 vastausten keskihajonnan. Jos laajennat tämän kaavan rivin ylitse, näet, että kysymyksen 3 vastauksilla on suurin keskihajonta. Jos tulokset edustavat näytteen sijasta vastauksia koko tutkittavalta populaatiolta, käytä KESKIHAJONTA-funktion sijasta KESKIHAJONTAP-funktiota. Huomaa, että KESKIHAJONTA on VAR-funktion neliöjuuri. |
=VAR(B2:B11) tai =VARP(B2:B11) | Määrittää kysymyksen 1 vastausten varianssin. Jos laajennat tämän kaavan rivin ylitse, näet, että kysymyksen 5 vastauksilla on pienin varianssi. Jos tulokset edustavat näytteen sijasta vastauksia koko tutkittavalta populaatiolta, käytä VAR-funktion sijasta VARP-funktiota. Huomaa, että VAR on KESKIHAJONTA-funktion neliö. |