CONTAR.SI
La función CONTAR.SI devuelve el número de celdas de una colección que satisfacen una condición dada.
CONTAR.SI(matriz-prueba, condición)
matriz-prueba: la colección que contiene los valores que se quieren probar. matriz-prueba puede incluir cualquier valor.
condición: una expresión que compara o prueba valores y que tiene como resultado el valor booleano VERDADERO o FALSO. condición puede incluir operadores de comparación, constantes, el operador de concatenación (&), referencias y comodines. Puedes utilizar comodines para hacer coincidir cualquier carácter o varios caracteres en la expresión. Puedes utilizar un signo de interrogación (?) para representar un carácter, un asterisco (*) para representar varios caracteres y una tilde (~) para especificar que el siguiente carácter debe interpretarse como un carácter, no como un comodín. Toma en cuenta que condición también puede contener una función REGEX en lugar de comodines.
Notas
Cada valor de matriz-prueba es comparado con condición. Si el valor satisface la prueba condicional, se incluye en el recuento.
Ejemplos |
|---|
La información de la tabla siguiente no es importante, pero es útil para mostrar el tipo de argumentos que CONTAR.SI incluye en los resultados. Dada la siguiente tabla: |
A | B | C | D | |
|---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | VERDADERO | VERDADERO | FALSO | FALSO |
5 | 200 | 400 |
=CONTAR.SI(A1:D1, ">0") devuelve 4 porque todas las celdas de la colección tienen un valor mayor que 0. =CONTAR.SI(A1:D1, "<>100") devuelve 3 porque todas las celdas de la colección tienen un valor que no es 100. También puedes usar el operador ≠. =CONTAR.SI(A3:D3, ">=100") devuelve 3 porque los tres números son mayores o iguales que 100 y el valor de texto se ignora en la comparación. También puedes usar el operador ≥. =CONTAR.SI(A1:D5, "=ipsum") devuelve 1 porque la cadena de prueba "ipsum" aparece una vez en la colección a la que hace referencia el intervalo. =CONTAR.SI(A1:D5, "=*t") devuelve 2 porque una cadena acabada en "t" aparece dos veces en la colección a la que hace referencia el intervalo. |
Ejemplo que usa REGEX |
|---|
Dada la siguiente tabla: |
A | B | |
|---|---|---|
1 | 45 | marina@ejemplo.com |
2 | 41 | Aarón |
3 | 29 | miguel@ejemplo.com |
4 | 64 | katrina@ejemplo.com |
5 | 12 | Sara |
=CONTAR.SI(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) devuelve el número de celdas en B1:B5 que contienen una dirección de correo electrónico. |
Ejemplo: resultados de una encuesta |
|---|
Este ejemplo reúne los ejemplos utilizados en las funciones estadísticas. Está basado en una hipotética encuesta. La encuesta era corta (sólo cinco preguntas) y tuvo un número muy limitado de entrevistados (10). Cada pregunta podía ser respondida en una escala de 1 a 5 (tal vez el intervalo entre "nunca" y "siempre"), o no respondida. A cada encuesta se le asignó un número (ID) antes de su envío. La tabla siguiente muestra los resultados. Las preguntas que fueron contestadas fuera del intervalo (incorrectas) o no fueron contestadas se indican con una celda vacía en la tabla. |
A | B | C | D | E | M | |
|---|---|---|---|---|---|---|
1 | ID | P1 | P2 | P3 | P4 | P5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
Para ilustrar algunas de las funciones, supondremos que el número de la encuesta incluye un prefijo alfabético y que la escala va de A a E, en lugar de 1 a 5. La tabla tendría este aspecto: |
A | B | C | D | E | M | |
|---|---|---|---|---|---|---|
1 | ID | P1 | P2 | P3 | P4 | P5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
Utilizando esta tabla de datos y algunas de las funciones estadísticas disponibles, se puede recoger información sobre los resultados de la encuesta. Ten presente que el ejemplo es intencionadamente pequeño, por lo que los resultados pueden parecer obvios. Sin embargo, con 50, 100 o más entrevistados y, tal vez, más preguntas, los resultados no serían obvios. |
Función y argumentos | Descripción del resultado |
|---|---|
=COEF.DE.CORREL (B2:B11, C2:C11) | Determina la correlación entre la pregunta 1 y la 2 utilizando análisis de regresión lineal. La correlación es una medida de cuánto dos variables (en este caso, respuestas a preguntas de una encuesta) cambian juntas. Específicamente, esto responde a la cuestión: si un entrevistado responde a la pregunta 1 con un valor superior (o inferior) al promedio para la pregunta 1, ¿responderá también a la pregunta 2 con un valor superior (o inferior) al promedio para la pregunta 2? En este caso, las respuestas no están particularmente bien correlacionadas (-0.1732). |
=CONTAR(A2:A11) o =CONTARA(A2:A11) | Determina el número total de encuestas devueltas (10). Ten en cuenta que si el número no era numérico, es necesario utilizar CONTARA en lugar de CONTAR. |
=CONTAR(B2:B11) o =CONTARA(B2:B11) | Determina el número total de respuestas a la primera pregunta (9). Extendiendo esta fórmula por la fila, se puede determinar el número total de respuestas a cada pregunta. Puesto que el dato es numérico, CONTARA devuelve el mismo resultado. En cambio, si la encuesta hubiera utilizado de A a E en lugar de 1 a 5, habría sido necesario utilizar CONTARA para contar los resultados. |
=CONTAR.BLANCO(B2:B11) | Determina el número de celdas vacías, que representan respuestas incorrectas o preguntas no contestadas. Si extendieras esta fórmula por la fila, verías que la pregunta 3 (columna D) tiene 3 respuestas incorrectas o no contestadas. Esto podría producir la revisión de la pregunta para ver si era controvertida o estaba mal expresada, porque ninguna otra pregunta ha tenido más de una respuesta incorrecta o no respondida. |
=CONTAR.SI(B2:B11, "=5") | Determina el número de entrevistados que dieron un 5 a una pregunta en concreto (en este caso, la pregunta 1). Si extendieras esta fórmula por la fila, te enterarías de que sólo las preguntas 1 y 4 tuvieron entrevistados que dieran a la pregunta un 5. Si la encuesta hubiese utilizado de A a E como intervalo, deberías haber usado =CONTAR.SI(B2:B11, "=E"). |
=CONTAR.SI(B2:B11, "<>5") | Determina el número de entrevistados que no dieron un 5 a una pregunta en concreto (en este caso, la pregunta 1). |
=COVAR(B2:B11,C2:C11) | Determina la covarianza de la pregunta 1 y la pregunta 2. La covarianza es una medida de cuánto dos variables (en este caso, respuestas a preguntas de una encuesta) cambian juntas. Específicamente, esto responde a la cuestión: si un entrevistado responde a la pregunta 1 con un valor superior (o inferior) al promedio para la pregunta 1, ¿responderá también a la pregunta 2 con un valor superior (o inferior) al promedio para la pregunta 2? Nota: COVAR no funcionará si la tabla utiliza una escala de A a E, porque requiere argumentos numéricos. |
=DESVEST(B2:B11) o =DESVESTP(B2:B11) | Determina la desviación estándar (una medida de dispersión) de las respuestas a la pregunta 1. Si se extiende esta fórmula por la fila, veremos que las respuestas a la pregunta 3 tuvieron la mayor desviación estándar. Si los resultados representaran respuestas de toda la población estudiada, en lugar de sólo una muestra, se hubiera utilizado DEVESTP en lugar de DESVEST. Observa que DESVEST es la raíz cuadrada de VAR. |
=VAR(B2:B11) o =VARP(B2:B11) | Determina la varianza (una medida de dispersión) de las respuestas a la pregunta 1. Si extendieras esta fórmula por la fila, verías que las respuestas a la pregunta 5 tuvieron la menor varianza. Si los resultados representaran respuestas de toda la población estudiada, en lugar de sólo una muestra, se hubiera utilizado VARP en lugar de VAR. Observa que VAR es el cuadrado de DESVEST. |