GJENNOMSNITTHVIS
GJENNOMSNITTHVIS-funksjonen returnerer gjennomsnittet (aritmetiske middelverdi) til cellene i et sett som tilfredsstiller en gitt betingelse.
GJENNOMSNITTHVIS(testverdier; betingelse; gjsn-verdier)
testverdier: En samling som inneholder verdiene som skal vurderes. testverdier kan inneholde en hvilken som helst verditype.
betingelse: Et uttrykk som sammenligner eller tester verdier og resultater i den boolske verdien SANN eller USANN. betingelse kan inkludere sammenligningsoperatorer, konstanter, ampersand sammenkjedingsoperatoren, referanser og jokertegn. Du kan bruke jokertegn til å erstatte ethvert enkelttegn eller flere tegn i uttrykket. Du kan bruke et ? (spørsmålstegn) for å representere ett tegn, en * (asterisk) for å representere flere tegn og en ~ (tilde) for å angi at neste tegn skal stemme overens framfor å brukes som et jokertegn. betingelse kan også inneholde en REGUTTR-funksjon i stedet for jokertegn.
gjsn-verdier: En valgfri samling som inneholder verdiene det skal regnes ut et gjennomsnitt av. gjsn-verdier er en referanse til én samling med celler som kun kan inneholde tallverdier eller boolske verdier.
Notater
Hver verdi sammenlignes med betingelse. Hvis verdien tilfredsstiller betingelsen, inkluderes den korresponderende verdien i gjsn-verdier i gjennomsnittet.
gjsn-verdier og testverdier (hvis spesifisert) må være av samme størrelse.
Hvis gjsn-verdier utelates, brukes testverdier for gjsn-verdier.
Hvis gjsn-verdier utelates eller er lik testverdier, kan testverdier kun inneholde tallverdier eller boolske verdier.
Vurder eventuelt å bruke GJENNOMSNITT.HVIS.SETT-funksjonen hvis det kreves mer enn én betingelse eller ett sett av testverdier.
Eksempler |
|---|
Gitt følgende tabell: |
A | B | C | D | |
|---|---|---|---|---|
1 | Alder | Kjønn | Status | Lønn |
2 | 35 | M | M | 71000 |
3 | 27 | F | M | 81000 |
4 | 42 | M | M | 86000 |
5 | 51 | M | S | 66000 |
6 | 28 | M | S | 52000 |
7 | 49 | F | S | 62000 |
8 | 63 | F | M | 89000 |
9 | 22 | M | M | 34000 |
10 | 29 | F | S | 42000 |
11 | 35 | F | M | 56000 |
12 | 33 | M | S | 62000 |
13 | 61 | M | M | 91000 |
=GJENNOMSNITTHVIS(A2:A13; "<40"; D2:D13) returnerer omtrent 56857, gjennomsnittslønnen til personer under 40 år. =GJENNOMSNITTHVIS(B2:B13; "=F"; D2:D13) returnerer 66000, gjennomsnittslønnen til kvinner (vises med en «F» i kolonne B). =GJENNOMSNITTHVIS(C2:C13; "S"; D2:D13) returnerer 56800, gjennomsnittslønnen til single (vises med en «S» i kolonne C). =GJENNOMSNITTHVIS(A2:A13; ">=40"; D2:D13) returnerer 78800, gjennomsnittslønnen til personer som er 40 år og eldre. |
Eksempel på bruk av REGUTTR |
|---|
Gitt følgende tabell: |
A | B | |
|---|---|---|
1 | 45 | john@appleseed.com |
2 | 41 | Aaron |
3 | 29 | janedoe@appleseed.com |
4 | 64 | jake@appleseed.com |
5 | 12 | Sarah |
=GJENNOMSNITTHVIS(B1:B5; REGUTTR("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2;4})"); A1:A5) returnerer 46, gjennomsnittet av alle cellene i A1:A5 der tilsvarende celle i B1:B5 inneholder en e-postadresse. |